Version bump w/ changed udev handling by Julian Ospald

(Portage version: 2.1.10.49/cvs/Linux x86_64)

3 files changed, 88 insertions, 4 deletions

diff --git a/x11-misc/spacefm/ChangeLog b/x11-misc/spacefm/ChangeLog
index 9d862349469e..c070ae4902a3 100644
--- a/x11-misc/spacefm/ChangeLog
+++ b/x11-misc/spacefm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-misc/spacefm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/ChangeLog,v 1.21 2012/04/17 14:32:51 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/ChangeLog,v 1.22 2012/04/21 21:35:05 xmw Exp $
+
+*spacefm-0.7.6 (21 Apr 2012)
+
+  21 Apr 2012; Michael Weber <xmw@gentoo.org> +spacefm-0.7.6.ebuild,
+  spacefm-9999.ebuild:
+  Version bump w/ changed udev handling by Julian Ospald
 
   17 Apr 2012; Samuli Suominen <ssuominen@gentoo.org> -spacefm-0.7.1.ebuild,
   -spacefm-0.7.2.ebuild, -spacefm-0.7.3.ebuild, metadata.xml:
diff --git a/x11-misc/spacefm/spacefm-0.7.6.ebuild b/x11-misc/spacefm/spacefm-0.7.6.ebuild
new file mode 100644
index 000000000000..13bc28ee5614
--- /dev/null
+++ b/x11-misc/spacefm/spacefm-0.7.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/spacefm-0.7.6.ebuild,v 1.1 2012/04/21 21:35:05 xmw Exp $
+
+EAPI=4
+
+inherit fdo-mime linux-info
+
+DESCRIPTION="A multi-panel tabbed file manager"
+HOMEPAGE="http://ignorantguru.github.com/spacefm/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="dev-libs/glib:2
+	dev-util/desktop-file-utils
+	sys-apps/dbus
+	>=sys-fs/udev-143
+	virtual/freedesktop-icon-theme
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:2
+	x11-libs/pango
+	x11-libs/startup-notification
+	x11-misc/shared-mime-info"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+src_configure() {
+	econf \
+		--htmldir=/usr/share/doc/${PF}/html \
+		--disable-hal \
+		--enable-inotify
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	einfo ""
+	elog "To mount as non-root user you need one of the following:"
+	elog "  sys-apps/pmount"
+	elog "  sys-fs/udisks:0"
+	elog "  sys-fs/udisks:2"
+	elog "To perform as root functionality you need one of the following:"
+	elog "  x11-misc/ktsuss"
+	elog "  x11-libs/gksu"
+	elog "  kde-base/kdesu"
+	elog "Other optional dependencies:"
+	elog "  sys-process/lsof (device processes)"
+	elog "  virtual/eject (eject media)"
+	einfo
+	if ! has_version 'sys-fs/udisks' ; then
+		elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
+		elog "you may need to enable kernel polling for device media changes to be detected."
+		elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
+		has_version '<sys-fs/udev-173' && ewarn "You need at least udev-173"
+		kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
+		einfo
+	fi
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
diff --git a/x11-misc/spacefm/spacefm-9999.ebuild b/x11-misc/spacefm/spacefm-9999.ebuild
index eed332f6567a..aa9551ec2c1a 100644
--- a/x11-misc/spacefm/spacefm-9999.ebuild
+++ b/x11-misc/spacefm/spacefm-9999.ebuild
@@ -1,13 +1,13 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/spacefm-9999.ebuild,v 1.3 2012/04/17 14:04:34 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/spacefm/spacefm-9999.ebuild,v 1.4 2012/04/21 21:35:05 xmw Exp $
 
 EAPI=4
 
 EGIT_REPO_URI="git://github.com/IgnorantGuru/${PN}.git"
 EGIT_BRANCH="next"
 
-inherit fdo-mime git-2
+inherit fdo-mime git-2 linux-info
 
 DESCRIPTION="A multi-panel tabbed file manager"
 HOMEPAGE="http://ignorantguru.github.com/spacefm/"
@@ -55,7 +55,15 @@ pkg_postinst() {
 	elog "Other optional dependencies:"
 	elog "  sys-process/lsof (device processes)"
 	elog "  virtual/eject (eject media)"
-	einfo ""
+	einfo
+	if ! has_version 'sys-fs/udisks' ; then
+		elog "When using SpaceFM without udisks, and without the udisks-daemon running,"
+		elog "you may need to enable kernel polling for device media changes to be detected."
+		elog "See /usr/share/doc/${PF}/html/spacefm-manual-en.html#devices-kernpoll"
+		has_version '<sys-fs/udev-173' && ewarn "You need at least udev-173"
+		kernel_is lt 2 6 38 && ewarn "You need at least kernel 2.6.38"
+		einfo
+	fi
 }
 
 pkg_postrm() {