New snapshot with latest upstream fix plus a patch for bug #413997

(Portage version: 2.1.11.24/cvs/Linux x86_64)

1 files changed, 78 insertions, 0 deletions

diff --git a/x11-wm/openbox/openbox-3.5.0_p20121006.ebuild b/x11-wm/openbox/openbox-3.5.0_p20121006.ebuild
new file mode 100644
index 000000000000..3401422f840b
--- /dev/null
+++ b/x11-wm/openbox/openbox-3.5.0_p20121006.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/openbox/openbox-3.5.0_p20121006.ebuild,v 1.1 2012/10/06 17:38:11 hwoarang Exp $
+
+EAPI="4"
+inherit multilib autotools eutils
+
+DESCRIPTION="A standards compliant, fast, light-weight, extensible window manager"
+HOMEPAGE="http://openbox.org/"
+SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${P}.tar.gz
+branding? ( http://dev.gentoo.org/~hwoarang/distfiles/surreal-gentoo.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="branding debug imlib nls python session startup-notification static-libs"
+
+RDEPEND="dev-libs/glib:2
+	>=dev-libs/libxml2-2.0
+	python? ( dev-python/pyxdg )
+	>=media-libs/fontconfig-2
+	x11-libs/libXft
+	x11-libs/libXrandr
+	x11-libs/libXt
+	>=x11-libs/pango-1.8[X]
+	imlib? ( media-libs/imlib2 )
+	startup-notification? ( >=x11-libs/startup-notification-0.8 )
+	x11-libs/libXinerama"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	x11-proto/xextproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xineramaproto"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-gnome-session-3.4.9.patch
+	epatch "${FILESDIR}"/${P/_p*/}-fix-desktop-files.patch
+	epatch "${FILESDIR}"/${P}-javaswing.patch
+	sed -i \
+		-e "s:-O0 -ggdb ::" \
+		-e 's/-fno-strict-aliasing//' \
+		"${S}"/m4/openbox.m4 || die
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir=/usr/share/doc/${PF} \
+		$(use_enable debug) \
+		$(use_enable imlib imlib2) \
+		$(use_enable nls) \
+		$(use_enable startup-notification) \
+		$(use_enable session session-management) \
+		$(use_enable static-libs static) \
+		--with-x
+}
+
+src_install() {
+	dodir /etc/X11/Sessions
+	echo "/usr/bin/openbox-session" > "${D}/etc/X11/Sessions/${PN}"
+	fperms a+x /etc/X11/Sessions/${PN}
+	emake DESTDIR="${D}" install
+	if use branding; then
+		insinto /usr/share/themes
+		doins -r "${WORKDIR}"/Surreal_Gentoo
+		# make it the default theme
+		sed -i \
+			"/<theme>/{n; s@<name>.*</name>@<name>Surreal_Gentoo</name>@}" \
+			"${D}"/etc/xdg/openbox/rc.xml \
+			|| die "failed to set Surreal Gentoo as the default theme"
+	fi
+	! use static-libs && rm "${D}"/usr/$(get_libdir)/lib{obt,obrender}.la
+	! use python && rm "${D}"/usr/libexec/openbox-xdg-autostart
+}