Version bump. Introduce USE="xscreensaver" for programs listed in the xflock4 script (for X screen locking).

(Portage version: 2.2.0_alpha100/cvs/Linux x86_64)

2 files changed, 70 insertions, 1 deletions

diff --git a/xfce-base/xfce4-session/ChangeLog b/xfce-base/xfce4-session/ChangeLog
index 40f04584ac11..d2cf1dadd9e3 100644
--- a/xfce-base/xfce4-session/ChangeLog
+++ b/xfce-base/xfce4-session/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for xfce-base/xfce4-session
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.156 2012/04/14 09:29:43 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/ChangeLog,v 1.157 2012/04/20 20:15:55 ssuominen Exp $
+
+*xfce4-session-4.9.2 (20 Apr 2012)
+
+  20 Apr 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +xfce4-session-4.9.2.ebuild:
+  Version bump. Introduce USE="xscreensaver" for programs listed in the xflock4
+  script (for X screen locking).
 
 *xfce4-session-4.9.1 (14 Apr 2012)
 
diff --git a/xfce-base/xfce4-session/xfce4-session-4.9.2.ebuild b/xfce-base/xfce4-session/xfce4-session-4.9.2.ebuild
new file mode 100644
index 000000000000..f8a7129391d8
--- /dev/null
+++ b/xfce-base/xfce4-session/xfce4-session-4.9.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/xfce-base/xfce4-session/xfce4-session-4.9.2.ebuild,v 1.1 2012/04/20 20:15:55 ssuominen Exp $
+
+EAPI=4
+inherit xfconf
+
+DESCRIPTION="A session manager for the Xfce desktop environment"
+HOMEPAGE="http://docs.xfce.org/xfce/xfce4-session/start"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="consolekit debug gnome-keyring policykit udev +xscreensaver"
+
+COMMON_DEPEND=">=dev-libs/dbus-glib-0.98
+	x11-apps/iceauth
+	x11-libs/libSM
+	>=x11-libs/libwnck-2.22:1
+	x11-libs/libX11
+	>=xfce-base/libxfce4util-4.9.1
+	>=xfce-base/libxfce4ui-4.9.2
+	>=xfce-base/xfconf-4.9.1
+	gnome-keyring? ( >=gnome-base/libgnome-keyring-2.22 )
+	!xfce-base/xfce-utils"
+RDEPEND="${COMMON_DEPEND}
+	x11-apps/xrdb
+	x11-misc/xdg-user-dirs
+	consolekit? ( || ( sys-auth/consolekit >=sys-apps/systemd-40 ) )
+	policykit? ( >=sys-auth/polkit-0.104-r1 )
+	udev? ( >=sys-power/upower-0.9.15 )
+	xscreensaver? ( || (
+		>=x11-misc/xscreensaver-5.15
+		gnome-extra/gnome-screensaver
+		>=x11-misc/xlockmore-5.38
+		>=x11-misc/slock-1
+		) )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	sys-devel/gettext"
+
+pkg_setup() {
+	XFCONF=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable gnome-keyring libgnome-keyring)
+		$(xfconf_use_debug)
+		)
+
+	DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
+}
+
+src_install() {
+	xfconf_src_install
+
+	local sessiondir=/etc/X11/Sessions
+	echo startxfce4 > "${T}"/Xfce4
+	exeinto ${sessiondir}
+	doexe "${T}"/Xfce4
+	dosym Xfce4 ${sessiondir}/Xfce
+}