1 files changed, 35 insertions, 0 deletions
diff --git a/sys-devel/bin86/bin86-0.16.20-r2.ebuild b/sys-devel/bin86/bin86-0.16.20-r2.ebuild
new file mode 100644
index 000000000000..54229f9fd101
--- /dev/null
+++ b/sys-devel/bin86/bin86-0.16.20-r2.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/bin86/bin86-0.16.20-r2.ebuild,v 1.1 2014/01/02 07:37:38 polynomial-c Exp $
+
+EAPI="5"
+
+inherit toolchain-funcs eutils
+
+DESCRIPTION="Assembler and loader used to create kernel bootsector"
+HOMEPAGE="http://v3.sk/~lkundrak/dev86/"
+SRC_URI="http://v3.sk/~lkundrak/dev86/${P}.tar.gz
+	https://github.com/lkundrak/dev86/commit/2c95336f19eeff761ecb858c5a2a58484bb3ceeb.patch -> ${PN}-0.16.20-fix_lilo_build.patch"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE=""
+
+src_prepare() {
+	sed -i \
+		-e '/^PREFIX/s:=.*:=$(DESTDIR)/usr:' \
+		-e '/^MANDIR/s:)/man/man1:)/share/man/man1:' \
+		-e '/^INSTALL_OPTS/s:-s::' \
+		-e "/^CFLAGS/s:=.*:=${CFLAGS} -D_POSIX_SOURCE ${CPPFLAGS}:" \
+		-e "/^LDFLAGS/s:=.*:=${LDFLAGS}:" \
+		Makefile || die
+	epatch "${FILESDIR}"/${PN}-0.16.17-amd64-build.patch \
+		"${DISTDIR}"/${P}-fix_lilo_build.patch
+	tc-export CC
+}
+
+src_install() {
+	dodir /usr/bin /usr/share/man/man1
+	default
+}