app-office/ledger/ledger-2.6.3-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-office/ledger/ledger-2.6.3-r1.ebuild,v 1.2 2011/09/05 22:32:58 radhermit Exp $

EAPI=4

inherit eutils elisp-common autotools

DESCRIPTION="A double-entry accounting system with a command-line reporting interface"
HOMEPAGE="http://ledger-cli.org/"
SRC_URI="http://cloud.github.com/downloads/jwiegley/${PN}/${P}.tar.gz"

LICENSE="BSD"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
SLOT="0"
IUSE="emacs debug gnuplot ofx static-libs xml vim-syntax"

DEPEND="dev-libs/gmp
	dev-libs/libpcre
	ofx? ( >=dev-libs/libofx-0.9 )
	xml? ( dev-libs/expat )
	emacs? ( virtual/emacs )
	gnuplot? ( sci-visualization/gnuplot )"
RDEPEND="${DEPEND}
	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )"

DOCS=(sample.dat README NEWS)

SITEFILE=50${PN}-gentoo.el

src_prepare() {
	sed -i -e "/ledger_LDFLAGS/d" Makefile.am
	eautoreconf
}

src_configure() {
	# Autodetection of dependencies may fail in the case of:
	# USE=emacs disabled, app-editors/emacs not installed, app-editors/xemacs installed
	use emacs || export EMACS=no
	econf \
		$(use_enable debug) \
		$(use_with emacs lispdir "${SITELISP}/${PN}") \
		$(use_enable ofx) \
		$(use_enable static-libs static) \
		$(use_enable xml)
}

src_install() {
	default

	# One script uses vi, the outher the Finance perl module
	# Did not add more use flags though
	exeinto /usr/share/${PN}/scripts
	doexe scripts/{entry,getquote,bal,bal-huquq}

	# Remove timeclock since it is part of Emacs
	rm -f "${ED}${SITELISP}/${PN}"/timeclock.*

	use emacs && elisp-site-file-install "${FILESDIR}/${SITEFILE}"

	if use gnuplot; then
		mv scripts/report ledger-report
		dobin ledger-report
	fi

	if use vim-syntax; then
		insinto /usr/share/vim/vimfiles/syntax
		doins ledger.vim
	fi

	use static-libs || find "${ED}" -name '*.la' -exec rm -f '{}' +
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}