app-vim/gist/gist-5.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-vim/gist/gist-5.0.ebuild,v 1.1 2011/06/25 08:04:38 radhermit Exp $

EAPI=4

inherit vim-plugin

MY_PN="Gist"
DESCRIPTION="vim plugin: interact with gists (gist.github.com)"
HOMEPAGE="http://www.vim.org/scripts/script.php?script_id=2423"
SRC_URI="https://github.com/vim-scripts/${MY_PN}.vim/tarball/${PV} -> ${P}.tar.gz"
LICENSE="BSD"
KEYWORDS="~amd64 ~x86"
IUSE=""

RDEPEND="net-misc/curl
	dev-vcs/git"

VIM_PLUGIN_HELPFILES="gist.txt"

src_unpack() {
	unpack ${A}
	mv *-${MY_PN}.vim-* "${S}"
}

src_prepare() {
	# There's good documentation included with the script, but it's not
	# in a helpfile. Since there's rather too much information to include
	# in a VIM_PLUGIN_HELPTEXT, we'll sed ourselves a help doc.
	mkdir "${S}"/doc
	sed -e '0,/"=\+$/d' -e '/" GetLatest.\+$/,9999d' -e 's/^" \?//' \
		-e 's/\(File: \)\([^.]\+\)\.vim/\1*\2.txt*/' \
		plugin/gist.vim \
		> doc/gist.txt

	rm README
}