dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xerces-c/xerces-c-2.7.0-r1.ebuild,v 1.3 2006/01/14 10:54:00 dertobi123 Exp $

inherit eutils multilib

MY_PV=${PV//./_}
MY_P=${PN}-src_${MY_PV}
DESCRIPTION="Xerces-C++ is a validating XML parser written in a portable subset of C++."
HOMEPAGE="http://xml.apache.org/xerces-c/index.html"
SRC_URI="mirror://apache/xml/xerces-c/source/${MY_P}.tar.gz"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 ~hppa ppc sparc x86"
IUSE="doc"

DEPEND="doc? ( app-doc/doxygen )"

S="${WORKDIR}"/xerces-c-src

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Fix multilib install
	epatch "${FILESDIR}"/${P}-multilib.patch
	epatch "${FILESDIR}"/${P}-libpath.patch
}

src_compile() {
	export XERCESCROOT="${S}"
	cd src/xercesc
	./runConfigure -plinux -P/usr
	emake -j1 || die
}

src_install () {
	export XERCESCROOT="${S}"
	cd "${S}"/src/xercesc
	make DESTDIR="${D}" MLIBDIR=$(get_libdir) install || die

	if use doc; then
		dodir /usr/share/doc/${P}
		cp -pPR "${S}"/samples "${D}"/usr/share/doc/${P}
		cd "${S}"/doc; doxygen
		dohtml -r html
	fi

	cd "${S}"
	dodoc STATUS credits.txt version.incl
	dohtml Readme.html

	unset XERCESCROOT
}