dev-python/docutils/docutils-0.6.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/docutils/docutils-0.6.ebuild,v 1.3 2009/11/14 17:05:54 arfrever Exp $

EAPI="2"
SUPPORT_PYTHON_ABIS="1"

inherit distutils eutils multilib

DESCRIPTION="Set of python tools for processing plaintext docs into HTML, XML, etc..."
HOMEPAGE="http://docutils.sourceforge.net/ http://pypi.python.org/pypi/docutils"
SRC_URI="mirror://sourceforge/docutils/${P}.tar.gz
	glep? ( mirror://gentoo/glep-0.4-r1.tbz2 )"

LICENSE="public-domain PYTHON BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="glep emacs"

DEPEND="dev-python/setuptools"
RDEPEND=""
# Emacs support is in PDEPEND to avoid a dependency cycle (bug #183242)
PDEPEND="emacs? ( || ( >=app-emacs/rst-0.4 >=virtual/emacs-23 ) )"

GLEP_SRC="${WORKDIR}/glep-0.4-r1"

DISTUTILS_USE_SEPARATE_SOURCE_DIRECTORIES="1"

src_prepare() {
	# Delete internal copies of optparse and textwrap modules.
	rm -f extras/{optparse.py,textwrap.py}
	# Fix installation of extra modules.
	epatch "${FILESDIR}/${PN}-0.6-extra_modules.patch"

	sed -e "s/from distutils.core/from setuptools/" -i setup.py || die "sed setup.py failed"

	# Fix tests.
	sed -e "/sys\.exit(result)/d" -i test/alltests.py || die "sed test/alltests.py failed"

	python_copy_sources --no-link
}

src_compile() {
	distutils_src_compile

	# Generate html docs from reStructured text sources.

	# make roman.py available for the doc building process
	ln -s extras/roman.py

	pushd tools > /dev/null

	# Place html4css1.css in base directory. This makes sure the
	# generated reference to it is correct.
	cp ../docutils/writers/html4css1/html4css1.css ..

	PYTHONPATH=.. ${python} ./buildhtml.py --stylesheet-path=../html4css1.css --traceback .. || die "buildhtml.py failed"

	popd > /dev/null

	# clean up after the doc building
	rm roman.py html4css1.css
}

src_test() {
	testing() {
		# Tests are broken with Python 3.
		[[ "${PYTHON_ABI:0:1}" == "3" ]] && return

		pushd test > /dev/null
		PYTHONPATH="../build/lib" ./alltests.py || return 1
		popd > /dev/null
	}
	python_execute_function -s testing
}

install_txt_doc() {
	local doc="${1}"
	local dir="txt/$(dirname ${doc})"
	docinto "${dir}"
	dodoc "${doc}"
}

src_install() {
	DOCS="*.txt"
	distutils_src_install

	# Tools
	cd tools
	for tool in *.py; do
		dobin "${tool}"
	done

	# Docs
	cd "${S}"
	dohtml -r docs tools
	# Manually install the stylesheet file
	insinto /usr/share/doc/${PF}/html
	doins docutils/writers/html4css1/html4css1.css
	for doc in $(find docs tools -name "*.txt"); do
		install_txt_doc "${doc}"
	done

	# installing Gentoo GLEP tools. Uses versioned GLEP distribution
	if use glep; then
		dobin ${GLEP_SRC}/glep.py || die "dobin failed"

		installation_of_glep_tools() {
			insinto $(python_get_sitedir)/docutils/readers
			newins ${GLEP_SRC}/glepread.py glep.py || die "newins reader failed"
			insinto $(python_get_sitedir)/docutils/transforms
			newins ${GLEP_SRC}/glepstrans.py gleps.py || die "newins transform failed"
			insinto $(python_get_sitedir)/docutils/writers
			doins -r ${GLEP_SRC}/glep_html || die "doins writer failed"
		}
		python_execute_function --action-message 'Installation of GLEP tools with Python ${PYTHON_ABI}...' installation_of_glep_tools
	fi
}

pkg_postinst() {
	python_mod_optimize docutils roman.py
}

pkg_postrm() {
	python_mod_cleanup
}