media-sound/qtscrobbler/qtscrobbler-0.8-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/qtscrobbler/qtscrobbler-0.8-r1.ebuild,v 1.2 2008/08/08 20:59:32 beandog Exp $

EAPI=1
inherit eutils qt4

MY_PN="qtscrob"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Updates a last.fm profile using information from a supported portable music player"
HOMEPAGE="http://qtscrob.sourceforge.net/"
SRC_URI="mirror://sourceforge/${MY_PN}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cli +qt4"

DEPEND="net-misc/curl
	qt4? ( || ( x11-libs/qt-gui:4 >=x11-libs/qt-4.3:4 ) )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	# Makefile for cli prog does not read CFLAGS env var.
	# This sed fixes this.
	cd "${S}/src/cli"
	sed -i -e "s:CFLAGS =.*:CFLAGS = \$(INCLUDE) `curl-config --cflags` ${CFLAGS}:" Makefile
}

src_compile() {
	if use cli; then
		cd "${S}/src/cli"
		emake || die "emake cli failed"
	fi
	if use qt4; then
		cd "${S}/src/qt"
		qmake "${MY_PN}.pro" || die "qmake qt4 gui failed"
		emake || die "emake qt4 gui failed"
	fi
}

src_install() {
	if use cli; then
		cd "${S}/src/cli"
		newbin scrobble-cli qtscrobbler-cli
	fi
	if use qt4; then
		cd "${S}/src/qt"
		newbin qtscrob qtscrobbler
		newicon resources/icons/128.png qtscrobbler.png
		make_desktop_entry qtscrobbler QtScrobbler
	fi
	cd "${S}"
	dodoc AUTHORS CHANGELOG README
}