blob: 89d16f15f214cc4a3425d2689eb27a43410777ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
|
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-0.99.6-r1.ebuild,v 1.3 2007/08/02 15:48:29 falco Exp $
WANT_AUTOMAKE="1.9"
inherit autotools libtool flag-o-matic eutils toolchain-funcs
DESCRIPTION="A network protocol analyzer formerly known as ethereal"
HOMEPAGE="http://www.wireshark.org/"
SRC_URI="mirror://sourceforge/wireshark/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="adns gtk ipv6 portaudio snmp ssl kerberos threads selinux"
RDEPEND="sys-libs/zlib
snmp? ( net-analyzer/net-snmp )
gtk? ( >=dev-libs/glib-2.0.4
=x11-libs/gtk+-2*
x11-libs/pango
dev-libs/atk )
!gtk? ( =dev-libs/glib-1.2* )
ssl? ( dev-libs/openssl )
!ssl? ( net-libs/gnutls )
net-libs/libpcap
dev-libs/libpcre
adns? ( net-libs/adns )
kerberos? ( virtual/krb5 )
portaudio? ( media-libs/portaudio )
selinux? ( sec-policy/selinux-wireshark )"
DEPEND="${RDEPEND}
>=dev-util/pkgconfig-0.15.0
dev-lang/perl
sys-devel/bison
sys-devel/flex
sys-apps/sed"
pkg_setup() {
# bug 119208
if has_version "<=dev-lang/perl-5.8.8_rc1" && built_with_use dev-lang/perl minimal ; then
ewarn "wireshark will not build if dev-lang/perl is compiled with"
ewarn "USE=minimal. Rebuild dev-lang/perl with USE=-minimal and try again."
ebeep 5
die "dev-lang/perl compiled with USE=minimal"
fi
if ! use gtk; then
ewarn "USE=-gtk will mean no gui called wireshark will be created and"
ewarn "only command line utils are available"
fi
}
src_unpack() {
unpack ${A}
cd "${S}"/epan
epatch "${FILESDIR}"/wireshark-except-double-free.diff
epatch "${FILESDIR}"/wireshark-epan_dissectors_packet-diameter.diff
cd "${S}"
epatch "${FILESDIR}"/${P}-gint64-warnings.patch
epatch "${FILESDIR}"/${P}-asneeded-r1.patch
epatch "${FILESDIR}"/${P}-libgcrypt.patch
epatch "${FILESDIR}"/${P}-lm.patch
#elibtoolize
AT_M4DIR="${S}/aclocal-fallback"
eautoreconf
}
src_compile() {
# optimization bug, see bug #165340
if [[ "$(gcc-version)" == "3.4" ]] ; then
elog "Found gcc 3.4, forcing -O3 into CFLAGS"
replace-flags -O? -O3
else
elog "Forcing -O into CFLAGS"
replace-flags -O? -O
fi
# see bug #133092
filter-flags -fstack-protector
local myconf
if use gtk; then
einfo "Building with gtk support"
else
einfo "Building without gtk support"
myconf="${myconf} --disable-wireshark --disable-warnings-as-errors"
# the asn1 plugin needs gtk
sed -i -e '/plugins.asn1/d' Makefile.in || die "sed failed"
sed -i -e '/^SUBDIRS/s/asn1//' plugins/Makefile.in || die "sed failed"
fi
# $(use_with lua) \
econf $(use_with ssl) \
$(use_enable ipv6) \
$(use_with adns) \
$(use_with kerberos krb5) \
$(use_with snmp net-snmp) \
$(use_with portaudio) \
$(use_enable gtk gtk2) \
$(use_enable threads) \
--without-ucd-snmp \
--enable-dftest \
--enable-randpkt \
--sysconfdir=/etc/wireshark \
--enable-editcap \
--enable-capinfos \
--enable-text2pcap \
${myconf} || die "econf failed"
# fixes an access violation caused by libnetsnmp - see bug 79068
use snmp && export MIBDIRS="${D}/usr/share/snmp/mibs"
emake || die "emake failed"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
insinto /usr/include/wiretap
doins wiretap/wtap.h
dodoc AUTHORS ChangeLog NEWS README*
insinto /usr/share/icons/hicolor/16x16/apps
newins "${S}"/image/hi16-app-wireshark.png wireshark.png
insinto /usr/share/icons/hicolor/32x32/apps
newins "${S}"/image/hi32-app-wireshark.png wireshark.png
insinto /usr/share/icons/hicolor/48x48/apps
newins "${S}"/image/hi48-app-wireshark.png wireshark.png
make_desktop_entry wireshark "Wireshark" wireshark
dosym tshark /usr/bin/tethereal
use gtk && dosym wireshark /usr/bin/ethereal
}
pkg_postinst() {
ewarn "Due to a history of security flaws in this piece of software, it may contain"
ewarn "more flaws. To protect yourself against malicious damage due to potential"
ewarn "flaws in this product, we recommend that you take the following security"
ewarn "precautions when running wireshark in an untrusted environment:"
ewarn "do not run any longer than you need to;"
ewarn "use in a root jail - preferably one that has been hardened with grsec like
rootjail protections;"
ewarn "use a hardened operating system;"
ewarn "do not listen to addition interfaces;"
ewarn "if possible, run behind a firewall;"
ewarn "take a capture with tcpdump and analyze running wireshark as a least
privileged user;"
ewarn "and subscribe to wireshark's announce list to be notified of newly discovered
vulnerabilities."
}
|
GitWeb