blob: 34b6bb0e727fcb09c0c955bf8c1e03b64c41c867 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
|
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/vmd/vmd-1.8.5.ebuild,v 1.10 2008/03/13 14:02:39 markusle Exp $
inherit eutils toolchain-funcs python
DESCRIPTION="Visual Molecular Dynamics"
LICENSE="vmd"
HOMEPAGE="http://www.ks.uiuc.edu/Research/vmd/"
SRC_URI="${P}.src.tar.gz"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="hardened"
RESTRICT="fetch"
DEPEND="app-shells/tcsh
x11-libs/libXft
virtual/opengl
x11-libs/fltk
=dev-lang/tcl-8.4*
=dev-lang/tk-8.4*
>=dev-lang/python-2.3
sci-biology/stride
sci-libs/netcdf
hardened? ( sys-apps/paxctl )"
VMD_DOWNLOAD="http://www.ks.uiuc.edu/Development/Download/download.cgi?PackageName=VMD"
pkg_nofetch() {
echo
einfo "Please download ${SRC_URI} from"
einfo "${VMD_DOWNLOAD}"
einfo "after agreeing to the license and then move it to "
einfo "${DISTDIR}"
echo
}
src_unpack() {
unpack ${A}
# apply LINUX-arch patches to vmd configure
epatch "${FILESDIR}"/${P}-config-gentoo.patch
# prepare the plugins
cd "${WORKDIR}"/plugins
sed -e "s:CC = gcc:CC = $(tc-getCC):" \
-e "s:CXX = g++:CXX = $(tc-getCXX):" \
-e "s:COPTO = -o :COPTO = -fPIC -o :" \
-e "s:LOPTO = -o :LOPTO = -fPIC -o :" \
-e "s:CCFLAGS = -O2 -Wall:CCFLAGS = ${CFLAGS}:" \
-e "s:CXXFLAGS = -O2 -Wall:CXXFLAGS = ${CXXFLAGS}:" \
-e "s:SHLD = gcc:SHLD = $(tc-getCC):" \
-i Make-arch || die "Failed to set up plugins Makefile"
# prepare vmd itself
cd "${S}"
sed -e "s:gentoo-bindir:${D}/usr/bin:" \
-e "s:gentoo-libdir:${D}/usr/$(get_libdir):" \
-i configure || die "failed to adjust install paths"
sed -e "s:gentoo-gcc:$(tc-getCC):" \
-e "s:gentoo-g++:$(tc-getCXX):" \
-e "s:gentoo-cflags:${CFLAGS}:" \
-i configure || die "Failed to adjust C compiler/flags"
sed -e "s:gentoo-plugindir:${WORKDIR}/plugins:" \
-i configure || die "Failed to set up linking to plugin files"
sed -e "s:gentoo-fltk-include:/usr/include/fltk-1.1:" \
-e "s:gentoo-fltk-libs:/usr/$(get_libdir)/fltk-1.1:" \
-i configure || die "failed setting up fltk"
sed -e "s:gentoo-netcdf-include:/usr/include:" \
-e "s:gentoo-netcdf-libs:/usr/$(get_libdir):" \
-i configure || die "failed to set up netcdf"
# get installed python version
python_version
local PY="python${PYVER}"
sed -e "s:gentoo-python-include:/usr/include/${PY}:" \
-e "s:gentoo-python-lib:/usr/$(get_libdir)/${PY}:" \
-e "s:gentoo-python-link:${PY}:" \
-i configure || die "failed setting up python"
sed -e "s:LINUXPPC:LINUX:g" \
-e "s:LINUXALPHA:LINUX:g" \
-e "s:LINUXAMD64:LINUX:g" \
-i "${S}"/bin/vmd || die "failed setting up vmd wrapper script"
local myconfig="LINUX OPENGL FLTK TK TCL PTHREADS PYTHON IMD NETCDF"
rm -f configure.options && echo $myconfig >> configure.options
./configure &> /dev/null || die "failed to configure"
}
src_compile() {
# build plugins
cd "${WORKDIR}"/plugins
make LINUX TCLINC="-I/usr/include" \
TCLLIB="-L/usr/$(get_libdir)/tcl8.4" || \
die "failed to build plugins"
# build vmd
cd "${S}"/src
make || die "failed to build vmd"
}
src_install() {
# install plugins
cd "${WORKDIR}"/plugins
PLUGINDIR=${D}/usr/$(get_libdir)/${PN}/plugins make distrib || \
die "failed to install plugins"
# install vmd
cd "${S}"/src
make install || die "failed to install vmd"
# export STRIDE_BIN so VMD find stride
echo "STRIDE_BIN=/usr/bin/stride" > "${T}"/99${PN} || \
die "Failed to create vmd env file"
doenvd "${T}"/99${PN} || die "Failed to install vmd env file"
# install docs
cd "${S}"
dodoc Announcement README doc/ig.pdf doc/ug.pdf
# remove some of the things we don't want and need in
# /usr/lib
cd "${D}"/usr/$(get_libdir)/vmd
rm -fr doc README Announcement LICENSE || \
die "failed to clean up /usr/lib/vmd directory"
# adjust path in vmd wrapper
sed -e "s:${D}::" -i "${D}"/usr/bin/${PN} \
|| die "failed to set up vmd wrapper script"
# adjust paxctl settings on hardened systems
if use hardened; then
/sbin/paxctl -pemrxs "${D}"/usr/$(get_libdir)/${PN}/${PN}_LINUX
fi
}
|
GitWeb