sci-physics/bullet/bullet-2.75.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/bullet/bullet-2.75.ebuild,v 1.1 2009/09/14 01:53:05 bicatali Exp $

EAPI=2
inherit eutils cmake-utils

DESCRIPTION="Continuous Collision Detection and Physics Library"
HOMEPAGE="http://www.bulletphysics.com/"
SRC_URI="http://bullet.googlecode.com/files/${P}.tgz"

LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples"

RDEPEND="virtual/glut"
DEPEND="${RDEPEND}"

src_prepare() {
	rm -f Extras/CDTestFramework/AntTweakBar/lib/libAntTweakBar.so
	sed -i \
		-e 's:DESTINATION lib:DESTINATION lib${LIB_SUFFIX}:g' \
		src/*/CMakeLists.txt || die
}

src_configure() {
	mycmakeargs="
		-DBUILD_SHARED_LIBS=ON
		-DBUILD_DEMOS=OFF
		-DBUILD_EXTRAS=OFF"
	cmake-utils_src_configure
	sed -e 's|@prefix@|${ROOT}usr|' \
		-e 's|@exec_prefix@|${prefix}|' \
		-e "s|@libdir@|\${exec_prefix}/$(get_libdir)|" \
		-e "s|@PACKAGE_VERSION@|${PV}|" \
		-e 's|Libs:.*$|Libs:-L${libdir} -lBulletDynamics -lBulletCollision -lLinearMath -lBulletSoftBody|' \
		bullet.pc.in > bullet.pc || die
}

src_install() {
	cmake-utils_src_install
	insinto /usr/$(get_libdir)/pkgconfig
	doins bullet.pc || die
	dodoc README ChangeLog AUTHORS
	if use doc; then
		insinto /usr/share/doc/${PF}
		doins *.pdf || die
	fi
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins -r Extras Demos || die
	fi
}