sci-physics/lhapdf/lhapdf-5.6.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-physics/lhapdf/lhapdf-5.6.0.ebuild,v 1.2 2009/02/20 13:29:32 flameeyes Exp $

inherit eutils fortran

DESCRIPTION="Les Houches Parton Density Function unified library"
HOMEPAGE="http://projects.hepforge.org/lhapdf/"
SRC_URI="http://www.hepforge.org/archive/lhapdf/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples python"

DEPEND="doc? ( app-doc/doxygen )
	python? ( dev-lang/swig )"
RDEPEND=""

pkg_setup() {
	local err
	# this is needed for formulas even with html output only
	if use doc && ! built_with_use app-doc/doxygen latex; then
		eerror "You need USE=latex in app-doc/doxygen for docs."
		err="${err} latex"
	fi

	[ -z "${err}" ] || die "Unsatisfied dependencies -- needs manual fix"

	FORTRAN="gfortran ifc"
	fortran_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	# do not create extra latex docs
	sed -i \
		-e 's/GENERATE_LATEX.*=YES/GENERATE_LATEX = NO/g' \
		ccwrap/Doxyfile || die
}

src_compile() {
	econf \
		$(use_enable python pyext) \
		$(use_enable doc doxygen) \
		|| die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc README TODO AUTHORS ChangeLog

	use doc && mv "${D}"/usr/share/${PN}/doc/html "${D}"/usr/share/doc/${PF}
	rm -rf "${D}"/usr/share/${PN}/doc
	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r examples || die
	fi
}