sci-visualization/nonolith-connect/nonolith-connect-1.0.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/nonolith-connect/nonolith-connect-1.0.1.ebuild,v 1.3 2012/12/11 09:48:39 ssuominen Exp $

EAPI=4

inherit base scons-utils toolchain-funcs udev user

DESCRIPTION="CEE (Control - Experiment - Explore) analog multitool"
HOMEPAGE="http://www.nonolithlabs.com/cee/"
SRC_URI="http://apps.nonolithlabs.com/download/source/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND="dev-libs/boost
	virtual/udev"
DEPEND="${RDEPEND}"

PATCHES=( "${FILESDIR}/${PV}-cflags-respect.patch" )

pkg_setup() {
	tc-export CC CXX
	enewuser nonolithd -1 -1 /dev/null usb
}

src_configure() {
	myesconsargs=(
		boost_static=0
	)
}

src_compile() {
	escons
}

src_install() {
	dobin nonolith-connect
	newinitd "${FILESDIR}"/nonolith-connect.initd nonolith-connect
	udev_dorules "${FILESDIR}"/60-nonolith-connect.rules
}

pkg_postinst() {
	einfo "Consider adding nonolith-connect to the default runlevel."
	einfo "Please connect your CEE hardware, start nonolith-connect "
	einfo "using the init script provided and then visit:"
	einfo "http://apps.nonolithlabs.com/setup"
}