sys-apps/reiserfsprogs/reiserfsprogs-3.6.4-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/reiserfsprogs/reiserfsprogs-3.6.4-r1.ebuild,v 1.3 2002/12/09 04:37:26 manson Exp $

S=${WORKDIR}/${P}
DESCRIPTION="Reiserfs Utilities"
SRC_URI="ftp://ftp.namesys.com/pub/reiserfsprogs/${P}.tar.gz"
HOMEPAGE="http://www.namesys.com"
KEYWORDS="x86 ~ppc ~sparc  ~alpha"
SLOT="0"
LICENSE="GPL-2"

DEPEND="virtual/glibc"

src_unpack() {
	unpack ${A}

	# NOTE: this patch needs to be applied to any architecture that has
	# /usr/include/asm/bitops.h entirely wrapped with #ifdef __KERNEL__.
	# This is needed because asm-i386/bitops.h is broken and reiserfsprogs
	# relies on the fact that it is broken. the reiserfsprogs people have
	# been made aware of this fact. hopefully this patch won't be needed
	# in future versions.
	# I bet sparc needs this patch too, but I don't have a machine to test on.
	if [ "${ARCH}" = "ppc" ]; then
		cd ${S}
		einfo "Applying asm/bitops.h patch"
		patch -p0 < ${FILESDIR}/reiserfsprogs-3.6.4-bitops.patch || die
	fi
}

src_compile() {
	cd ${S}
	./configure --prefix=/ || die
	emake || die
}

src_install() {
	make DESTDIR=${D} install || die
	dodir /usr/share
	dodoc AUTHORS COPYING ChangeLog INSTALL NEWS README

	cd ${D}
	mv man usr/share
	dosym /sbin/reiserfsck /sbin/fsck.reiserfs
}