blob: cf6549305c19f37bb143264caf464910d9eeb62d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/cryptsetup/cryptsetup-1.4.1-r1.ebuild,v 1.7 2014/03/01 22:49:18 mgorny Exp $
EAPI="4"
inherit linux-info libtool
MY_P=${P/_rc/-rc}
DESCRIPTION="Tool to setup encrypted devices with dm-crypt"
HOMEPAGE="http://code.google.com/p/cryptsetup/"
SRC_URI="http://cryptsetup.googlecode.com/files/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="nls selinux static"
S=${WORKDIR}/${MY_P}
LIB_DEPEND="dev-libs/libgpg-error[static-libs(+)]
>=dev-libs/popt-1.7[static-libs(+)]
>=sys-apps/util-linux-2.17.2[static-libs(+)]
>=dev-libs/libgcrypt-1.1.42:0[static-libs(+)]
>=sys-fs/lvm2-2.02.64[static-libs(+)]
virtual/udev[static-libs(+)]
>=sys-libs/e2fsprogs-libs-1.41[static-libs(+)]"
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
!<sys-apps/baselayout-2
!sys-fs/cryptsetup-luks
selinux? ( sys-libs/libselinux )"
DEPEND="${RDEPEND}
static? ( ${LIB_DEPEND} )"
pkg_setup() {
local CONFIG_CHECK="~DM_CRYPT ~CRYPTO ~CRYPTO_CBC"
local WARNING_DM_CRYPT="CONFIG_DM_CRYPT:\tis not set (required for cryptsetup)\n"
local WARNING_CRYPTO_CBC="CONFIG_CRYPTO_CBC:\tis not set (required for kernel 2.6.19)\n"
local WARNING_CRYPTO="CONFIG_CRYPTO:\tis not set (required for cryptsetup)\n"
check_extra_config
}
src_prepare() {
sed -i '/^LOOPDEV=/s:$: || exit 0:' tests/{compat,mode}-test
elibtoolize
}
src_configure() {
econf \
--sbindir=/sbin \
--enable-shared \
$(use_enable static static-cryptsetup) \
$(use_enable nls) \
$(use_enable selinux)
}
src_test() {
if [[ ! -e /dev/mapper/control ]] ; then
ewarn "No /dev/mapper/control found -- skipping tests"
return 0
fi
local p
for p in /dev/mapper /dev/loop* ; do
addwrite ${p}
done
default
}
src_install() {
emake DESTDIR="${D}" install
use static && { mv "${D}"/sbin/cryptsetup{.static,} || die ; }
dodoc TODO ChangeLog README NEWS
newconfd "${FILESDIR}"/1.0.6-dmcrypt.confd dmcrypt
newinitd "${FILESDIR}"/1.4.1-dmcrypt.rc dmcrypt
}
pkg_postinst() {
ewarn "This ebuild introduces a new set of scripts and configuration"
ewarn "than the last version. If you are currently using /etc/conf.d/cryptfs"
ewarn "then you *MUST* copy your old file to:"
ewarn "/etc/conf.d/dmcrypt"
ewarn "Or your encrypted partitions will *NOT* work."
elog "Please see the example for configuring a LUKS mountpoint"
elog "in /etc/conf.d/dmcrypt"
elog
elog "If you are using baselayout-2 then please do:"
elog "rc-update add dmcrypt boot"
elog "This version introduces a command line arguement 'key_timeout'."
elog "If you want the search for the removable key device to timeout"
elog "after 10 seconds add the following to your bootloader config:"
elog "key_timeout=10"
elog "A timeout of 0 will mean it will wait indefinitely."
elog
elog "Users using cryptsetup-1.0.x (dm-crypt plain) volumes must use"
elog "a compatibility mode when using cryptsetup-1.1.x. This can be"
elog "done by specifying the cipher (-c), key size (-s) and hash (-h)."
elog "For more info, see http://code.google.com/p/cryptsetup/wiki/FrequentlyAskedQuestions#6._Issues_with_Specific_Versions_of_cryptsetup"
}
|
GitWeb