sys-fs/ecryptfs-utils/ecryptfs-utils-30.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-30.ebuild,v 1.2 2007/11/11 06:29:34 mr_bones_ Exp $

inherit autotools

DESCRIPTION="eCryptfs userspace utilities"
HOMEPAGE="http://www.ecryptfs.org"
SRC_URI="mirror://sourceforge/ecryptfs/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="pam gtk openssl pkcs11 gpg doc"

RDEPEND="sys-apps/keyutils
	dev-libs/libgcrypt
	pam? ( sys-libs/pam )
	openssl? ( dev-libs/openssl )
	pkcs11? (
		dev-libs/openssl
		>=dev-libs/pkcs11-helper-1.04
	)
	gpg? ( app-crypt/gpgme )
	gtk? ( x11-libs/gtk+ )"
# perl required for man generation
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-lang/perl"

src_unpack() {
	unpack ${A}
	cd "${S}"
	# Until upstream move to autoconf-2.60
	eautoreconf
}

src_compile() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		$(use_enable pam) \
		$(use_enable openssl) \
		$(use_enable pkcs11 pkcs11-helper) \
		$(use_enable gpg) \
		$(use_enable gtk gui) \
		$(use_enable doc docs) \
		|| die
	emake || die
}

src_install(){
	emake DESTDIR="${D}" install || die
	fperms u+s /sbin/mount.ecryptfs
}