1 files changed, 63 insertions, 0 deletions
diff --git a/dev-python/traitsui/traitsui-4.0.1.ebuild b/dev-python/traitsui/traitsui-4.0.1.ebuild
new file mode 100644
index 0000000..acf4ee4
--- /dev/null
+++ b/dev-python/traitsui/traitsui-4.0.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/traitsui/traitsui-4.0.1.ebuild,v 1.1 2011/08/03 23:49:29 bicatali Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="3.* *-jython"
+DISTUTILS_SRC_TEST="nosetests"
+
+inherit distutils virtualx
+
+DESCRIPTION="Enthought Tool Suite: traits-capable user interfaces"
+HOMEPAGE="https://github.com/enthought/traitsui http://pypi.python.org/pypi/traitsui"
+SRC_URI="http://www.enthought.com/repo/ets/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="dev-python/pyface
+	dev-python/traits"
+DEPEND="dev-python/setuptools
+	doc? ( dev-python/sphinx )
+	test? (
+		${RDEPEND}
+		media-fonts/font-cursor-misc
+		media-fonts/font-misc-misc
+	)"
+
+DOCS="docs/*.txt"
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		einfo "Generation of documentation"
+		pushd docs > /dev/null
+		emake html || die "Generation of documentation failed"
+		popd > /dev/null
+	fi
+}
+
+src_test() {
+	VIRTUALX_COMMAND="distutils_src_test" virtualmake
+}
+
+src_install() {
+	find -name "*LICENSE*.txt" -delete
+	distutils_src_install
+
+	if use doc; then
+		pushd docs/build/html > /dev/null
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples || die "Installation of examples failed"
+	fi
+}