kde-apps/kget: 23.08.4 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/kde-apps/kget/Manifest b/kde-apps/kget/Manifest
new file mode 100644
index 0000000000..60a2425cb3
--- /dev/null
+++ b/kde-apps/kget/Manifest
@@ -0,0 +1 @@
+DIST kget-23.08.4.tar.xz 5566060 BLAKE2B 1c4b47d9b77e7abc38c36f9a242c8b930068eaef103a585154411f4c10bd31143f061cb469a13af65ba9fe675418331e84b409784919f273af3e2a4e7c22b185 SHA512 aba5a03a5c35564754b4583db30bbdb07daa1ffc8e689a7db1469e8aeacd907ecdb515adcf7b839448bdb31881779e38f579dbfc9282d008c225ccd2bb6f47a8
diff --git a/kde-apps/kget/kget-23.08.4.ebuild b/kde-apps/kget/kget-23.08.4.ebuild
new file mode 100644
index 0000000000..9d6fb3b8d8
--- /dev/null
+++ b/kde-apps/kget/kget-23.08.4.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Advanced download manager by KDE"
+HOMEPAGE="https://apps.kde.org/kget/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bittorrent gpg kde mms sqlite"
+
+RDEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	bittorrent? ( >=net-libs/libktorrent-21.07.80:5 )
+	gpg? ( app-crypt/gpgme:=[qt5] )
+	kde? ( kde-plasma/libkworkspace:5 )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bittorrent KF5Torrent)
+		$(cmake_use_find_package gpg Gpgmepp)
+		$(cmake_use_find_package kde LibKWorkspace)
+		$(cmake_use_find_package mms LibMms)
+		$(cmake_use_find_package sqlite SQLite3)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 756817: schedulertest fails, see also upstream commit 45735cfa
+	# filedeletertest hangs.
+	local myctestargs=(
+		-E "(schedulertest|filedeletertest)"
+	)
+
+	ecm_src_test
+}