blob: 948946ad69130e686a4b7c58e112841aef823e93 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=5
inherit cmake-utils
DESCRIPTION="LXDE-Qt desktop panel and plugins"
HOMEPAGE="http://www.lxde.org/"
if [[ ${PV} = *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="git://github.com/lxde/${PN}.git"
EGIT_BRANCH="master"
KEYWORDS=""
else
SRC_URI="mirror://sourceforge/lxde/${P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="LGPL-2.1+"
SLOT="0"
IUSE="+alsa +clock colorpicker cpuload +desktopswitch +kbindicator +mainmenu
+mount networkmonitor pulseaudio +quicklaunch screensaver sensors
+showdesktop sysstat +taskbar +tray +volume worldclock"
REQUIRED_USE="volume? ( || ( alsa pulseaudio ) )"
DEPEND="lxde-base/liblxqt
lxde-base/liblxqt-mount
lxde-base/libqtxdg
lxde-base/lxqt-globalkeys
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
x11-libs/libX11
cpuload? ( sys-libs/libstatgrab )
networkmonitor? ( sys-libs/libstatgrab )
sensors? ( sys-apps/lm_sensors )
sysstat? ( lxde-base/libsysstat )
volume? ( alsa? ( media-libs/alsa-lib )
pulseaudio? ( media-sound/pulseaudio ) )
worldclock? ( dev-libs/icu )"
RDEPEND="${DEPEND}
lxde-base/lxmenu-data"
src_configure() {
local mycmakeargs
for i in clock colorpicker cpuload desktopswitch kbindicator mainmenu mount \
networkmonitor quicklaunch screensaver sensors showdesktop sysstat \
taskbar tray volume worldclock; do
mycmakeargs+=( $(cmake-utils_use $i ${i^^}_PLUGIN) )
done
if use volume; then
mycmakeargs+=( $(cmake-utils_use alsa VOLUME_USE_ALSA)
$(cmake-utils_use pulseaudio VOLUME_USE_PULSEAUDIO) )
fi
cmake-utils_src_configure
}
|
GitWeb
