1 files changed, 66 insertions, 0 deletions
diff --git a/sci-mathematics/frama-c/frama-c-20100401.ebuild b/sci-mathematics/frama-c/frama-c-20100401.ebuild
new file mode 100644
index 000000000..ffcf9b023
--- /dev/null
+++ b/sci-mathematics/frama-c/frama-c-20100401.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="3"
+
+inherit autotools eutils
+
+DESCRIPTION="Frama-C is a suite of tools dedicated to the analysis of the source code of software written in C."
+HOMEPAGE="http://frama-c.com"
+NAME="Boron"
+SRC_URI="http://frama-c.com/download/${PN/-c/-c-$NAME}-${PV/_/-}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="apron doc gtk +ocamlopt +why"
+RESTRICT="strip"
+
+DEPEND=">=dev-lang/ocaml-3.10.2[ocamlopt?]
+		>=dev-ml/ocamlgraph-1.6[gtk?,ocamlopt?]
+		gtk? ( >=x11-libs/gtksourceview-2.8
+			>=gnome-base/libgnomecanvas-2.26
+			>=dev-ml/lablgtk-2.14[sourceview,gnomecanvas,ocamlopt?] )
+		sci-mathematics/ltl2ba
+		apron? ( sci-mathematics/apron )"
+RDEPEND="${DEPEND}"
+PDEPEND="why? ( >=sci-mathematics/why-2.26 )"
+
+S="${WORKDIR}/${PN/-c/-c-$NAME}-${PV/_/-}"
+
+src_prepare(){
+	rm share/libc/test.c
+	rm -Rf src/wp
+
+	epatch "${FILESDIR}/${P}-plugin_install.patch"
+	
+	touch config_file
+	eautoreconf
+}
+
+src_configure() {
+	if use gtk; then
+		myconf="--enable-gui"
+	else
+		myconf="--disable-gui"
+	fi
+
+	econf ${myconf} || die "econf failed"
+}
+
+src_compile() {
+	# dependencies can not be processed in parallel,
+	# this is the intended behavior.
+	emake -j1 depend || die "emake depend failed"
+	emake all top DESTDIR="/" || die "emake failed"
+}
+
+src_install(){
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc Changelog doc/README
+
+	if use doc; then
+		dodoc doc/manuals/*
+	fi
+}