sys-fs/multipath-tools: Bump to version 0.7.9

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 95 insertions, 0 deletions

diff --git a/sys-fs/multipath-tools/Manifest b/sys-fs/multipath-tools/Manifest
index f57fd5f06545..b596a4ab70ed 100644
--- a/sys-fs/multipath-tools/Manifest
+++ b/sys-fs/multipath-tools/Manifest
@@ -2,3 +2,4 @@ DIST multipath-tools-0.5.0.tar.bz2 184024 BLAKE2B 1e1b0fdd52bf0aaea3ed281e0cd89d
 DIST multipath-tools-0.6.4.tar.gz 285448 BLAKE2B 1b63c4e712e682965c595ed988a6590e181abd4d37779b72b52f4e415d4caba33df518a1ea1e3b460d15b5a78f4db5a75c1066439eb40c503023007c1f70752a SHA512 ec35c6c26c3b233ebece7136ea99dd4c0dff2927e7b543e7091219dc7065fe87e609a1eda9ab6d08399d44fe882d70c8dbe6be9ab175d154c5dd2d12ee1d86ea
 DIST multipath-tools-0.7.7.tar.gz 398460 BLAKE2B 39ffa02d782858d1200080d11aafc341793b83e421a40207eaaf5084cffe5ef5e9e860d60cd03c828c1eb941be2f762b9ad9c2ea21e29b5f129fb26bd6090d22 SHA512 87458f3eb0aaac09b22972c4ff26e332d64841a3d19fefce69cae662f1e2ce2df778e1795d5b4089b1110ec5081c6021aadbb902eeaeb764f989031cbe7da825
 DIST multipath-tools-0.7.8.tar.gz 415900 BLAKE2B 04c237e91f8e56484603d5b5ec7504da6be1caf9564d21a9fa4be7268fbb88089b8446c959b57f859eb9696f39cbb82bffdcd3d0a6716da6487bedd5c18c0d8b SHA512 500a51f9e8c5cc0ad04cc69c39f657e8058a08750d506b447c4a1131ad7308d43de19d79e98fa8254c56cd7eb1e832c8ccbc439ce94054db7eeebcdf2bf225cb
+DIST multipath-tools-0.7.9.tar.gz 419377 BLAKE2B 29003b7ce2d673eb59d869e2165028654361ca31f49b8e810d90611db249a5183492959d3aef778b870df7c1d283004bda88f3cc6f760569247f1ccc61617379 SHA512 6b237f148c239938b9f46a1a8118fc070372d5f2cfe2021c26ad9ca15d37e8866390168b6a4f13adcc5538001354247e072559a0add33ce1fe8245ae64ed0a3c
diff --git a/sys-fs/multipath-tools/multipath-tools-0.7.9.ebuild b/sys-fs/multipath-tools/multipath-tools-0.7.9.ebuild
new file mode 100644
index 000000000000..6d0be1d4eb2e
--- /dev/null
+++ b/sys-fs/multipath-tools/multipath-tools-0.7.9.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit linux-info systemd toolchain-funcs udev vcs-snapshot toolchain-funcs
+
+DESCRIPTION="Device mapper target autoconfig"
+HOMEPAGE="http://christophe.varoqui.free.fr/"
+SRC_URI="https://git.opensvc.com/?p=multipath-tools/.git;a=snapshot;h=${PV};sf=tgz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="systemd rbd"
+
+RDEPEND="
+	dev-libs/json-c:=
+	dev-libs/libaio
+	dev-libs/userspace-rcu:=
+	>=sys-fs/lvm2-2.02.45
+	>=virtual/udev-171
+	sys-libs/readline:0=
+	rbd? ( sys-cluster/ceph )
+	systemd? ( sys-apps/systemd )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+CONFIG_CHECK="~DM_MULTIPATH"
+
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.7.5-respect-flags.patch )
+
+get_systemd_pv() {
+	use systemd && \
+		$(tc-getPKG_CONFIG) --modversion systemd
+}
+
+pkg_pretend() {
+	linux-info_pkg_setup
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# The upstream lacks any way to configure the build at present
+	# and ceph is a huge dependency, so we're using sed to make it
+	# optional until the upstream has a proper configure system
+	if ! use rbd ; then
+		sed \
+			-e "s/libcheckrbd.so/# libcheckrbd.so/" \
+			-e "s/-lrados//" \
+			-i libmultipath/checkers/Makefile \
+			|| die
+	fi
+}
+
+src_compile() {
+	# LIBDM_API_FLUSH involves grepping files in /usr/include,
+	# so force the test to go the way we want #411337.
+	emake \
+		CC="$(tc-getCC)" \
+		LIBDM_API_FLUSH=1 SYSTEMD="$(get_systemd_pv)"
+}
+
+src_install() {
+	dodir /sbin /usr/share/man/man{5,8}
+	emake \
+		DESTDIR="${D}" \
+		SYSTEMD=$(get_systemd_pv) \
+		unitdir="$(systemd_get_systemunitdir)" \
+		libudevdir='${prefix}'/"$(get_udevdir)" \
+		install
+
+	newinitd "${FILESDIR}"/rc-multipathd multipathd
+	newinitd "${FILESDIR}"/multipath.rc multipath
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "If you need multipath on your system, you must"
+		elog "add 'multipath' into your boot runlevel!"
+	fi
+}