app-accessibility/orca: bump to 3.26.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/app-accessibility/orca/Manifest b/app-accessibility/orca/Manifest
index 403bf5cfaaff..b68caa34ece5 100644
--- a/app-accessibility/orca/Manifest
+++ b/app-accessibility/orca/Manifest
@@ -1 +1,2 @@
 DIST orca-3.24.0.tar.xz 2391740 BLAKE2B 1f294bc8e1c593690c511f0d7d660230c420b33de59c8b1e78ee8d7b16f973b9fff9ce4d656de7202ffd5789ae3604d030c442e8c35eecfd5c5dca058031e996 SHA512 9aa65b534f69bb4a1b800e715776416843ac3756ec1267feca3c66476e34e54f6744f70c0f8ac8868a009d38b6cc165267268491a9ad29ebbd3601dba09d424c
+DIST orca-3.26.0.tar.xz 2407368 BLAKE2B e04a891a2f2478b5b5f556a423c073f8c64de78d1f744d41d292cd783edc2ba0e57824ba3afb1f1b58f62503a204003d97e1fb652df307f34ae6838bce44389c SHA512 ca3a60b36d9528cf424e01d7a1aad75a8e14e46a6c93330b8e439bd44832dbc44897657b8da3c583501ce8c835f589209f1b3969ab110766cb1dc099defd2445
diff --git a/app-accessibility/orca/orca-3.26.0.ebuild b/app-accessibility/orca/orca-3.26.0.ebuild
new file mode 100644
index 000000000000..88ecd17c1e56
--- /dev/null
+++ b/app-accessibility/orca/orca-3.26.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{4,5,6} )
+PYTHON_REQ_USE="threads"
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.26:2
+	>=app-accessibility/at-spi2-core-2.26:2[introspection]
+	>=dev-libs/atk-2.26
+	>=dev-libs/glib-2.28:2
+	dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.18:3[${PYTHON_USEDEP}]
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	braille? (
+		>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+		dev-libs/liblouis[python,${PYTHON_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+	dev-libs/atk[introspection]
+	>=dev-python/pyatspi-2.26[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	dev-util/itstool
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_prepare() {
+	gnome2_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir gnome2_src_compile
+}
+
+src_install() {
+	installing() {
+		gnome2_src_install
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#!'"${PYTHON}:#!/usr/bin/python:" \
+			-i src/orca/orca || die
+		python_doscript src/orca/orca
+	}
+	python_foreach_impl run_in_build_dir installing
+}