app-admin/emacs-updater: add 1.18

Closes: https://bugs.gentoo.org/931064
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/app-admin/emacs-updater/emacs-updater-1.18.ebuild b/app-admin/emacs-updater/emacs-updater-1.18.ebuild
new file mode 100644
index 000000000000..f9cebdcb57a7
--- /dev/null
+++ b/app-admin/emacs-updater/emacs-updater-1.18.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Rebuild Emacs packages"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+DEPEND="|| ( sys-apps/util-linux app-misc/getopt )"
+RDEPEND="${DEPEND}
+	>=app-editors/emacs-23.1:*
+	>=app-portage/portage-utils-0.80"
+
+src_prepare() {
+	default
+
+	if ! has_version sys-apps/util-linux; then
+		# BSD ships a dumb getopt(1), so use getopt-long instead
+		sed -i -e '/^GETOPT=/s/getopt/&-long/' emacs-updater || die
+	fi
+
+	if [[ -n ${EPREFIX} ]]; then
+		sed -i -e "1s:/:${EPREFIX}/:" \
+			-e "s:^\([[:upper:]]*=\)/:\1${EPREFIX}/:" \
+			emacs-updater || die
+	fi
+}
+
+src_install() {
+	dosbin emacs-updater
+	doman emacs-updater.8
+}