app-emacs/lsp-mode: compile clients; enable tests

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 59 insertions, 39 deletions

diff --git a/app-emacs/lsp-mode/lsp-mode-8.0.0-r1.ebuild b/app-emacs/lsp-mode/lsp-mode-8.0.0-r1.ebuild
new file mode 100644
index 000000000000..ec668118c0b9
--- /dev/null
+++ b/app-emacs/lsp-mode/lsp-mode-8.0.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=26.1
+
+inherit elisp
+
+DESCRIPTION="Emacs client/library for the Language Server Protocol"
+HOMEPAGE="https://emacs-lsp.github.io/lsp-mode/"
+SRC_URI="https://github.com/emacs-lsp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=app-emacs/dash-2.18.0
+	>=app-emacs/f-0.20.0
+	app-emacs/ht
+	app-emacs/lv
+	app-emacs/markdown-mode
+	app-emacs/spinner
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-emacs/deferred
+		app-emacs/ecukes
+		app-emacs/el-mock
+		app-emacs/ert-runner
+		app-emacs/espuds
+		app-emacs/flycheck
+		app-emacs/undercover
+	)
+"
+
+DOCS=( AUTHORS CHANGELOG.org README.md refcard )
+BYTECOMPFLAGS="-L . -L clients"
+ELISP_REMOVE="test/lsp-clangd-test.el test/lsp-common-test.el
+	test/lsp-integration-test.el"  # Remove failing tests
+SITEFILE="50${PN}-gentoo.el"
+
+src_compile() {
+	elisp_src_compile
+	elisp-compile clients/*.el
+}
+
+src_test() {
+	ert-runner -L clients --reporter ert+duration -t "!no-win" -t "!org" || die
+}
+
+src_install() {
+	elisp_src_install
+	elisp-install ${PN}/clients clients/*
+}
diff --git a/app-emacs/lsp-mode/lsp-mode-8.0.0.ebuild b/app-emacs/lsp-mode/lsp-mode-8.0.0.ebuild
deleted file mode 100644
index 610948576522..000000000000
--- a/app-emacs/lsp-mode/lsp-mode-8.0.0.ebuild
+++ /dev/null
@@ -1,39 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-NEED_EMACS=26.1
-
-inherit elisp
-
-IUSE=""
-
-DESCRIPTION="Emacs client/library for the Language Server Protocol"
-HOMEPAGE="https://emacs-lsp.github.io/lsp-mode/"
-SRC_URI="https://github.com/emacs-lsp/lsp-mode/archive/${PV}.tar.gz -> ${P}.tar.gz"
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64"
-DOCS="CHANGELOG.org README.md"
-
-SITEFILE="50${PN}-gentoo.el"
-
-RDEPEND="
-	>=app-emacs/dash-2.18.0
-	>=app-emacs/f-0.20.0
-	>=app-emacs/ht-2.3
-	app-emacs/lv
-	>=app-emacs/markdown-mode-2.3
-	>=app-emacs/spinner-1.7.3
-"
-DEPEND=${RDEPEND}
-
-# Requires unpackaged dependencies, e.g. Cask
-RESTRICT="test"
-
-src_install() {
-	elisp_src_install
-
-	elisp-install ${PN}/clients clients/*
-}