app-emulation/winetricks: add 20240105

Also update copyright year for 99999999.

Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

3 files changed, 93 insertions, 1 deletions

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
index 268ad2e03048..bb6973b41b47 100644
--- a/app-emulation/winetricks/Manifest
+++ b/app-emulation/winetricks/Manifest
@@ -1,2 +1,3 @@
 DIST winetricks-20230212.tar.gz 694504 BLAKE2B 8f36a618edd0b17ccb7dbd1f054d45d2d35c3c8e5bfb2f12d91b8f9c87c9942db5b430a2b3017a42c3900dfe8f0510a6b8a6d78035e3fb467d88a3db0b64eff8 SHA512 3d2211091754a2a254d5ac8dab27d59d488d512149d8060828cf9d69df96f5ccad183f2ba9f2172452a2ae322236e86e7fce560836a2bc05dc9a36c2a422f245
+DIST winetricks-20240105.tar.gz 675763 BLAKE2B 0ca29d06ae35c95027ead0da2fa26b2950b4b4d495b61c972b9f93ae26fcadc7891931224bc2a8776e06f8bf2816e2fd5b84a0ef342de296aae20129dd5480b0 SHA512 254b505e1175477df3a27b361f227a02a2346a1b7ace255b6170e8bd463883dda8fef9fcbf2cd54606d69742fd6236f9aa58f589e2a34eb66bd04dfaa7bd6799
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 BLAKE2B 54a4502f6e8ef15d21b02c43e3ce599e32d476c2559246064de14cc4ce2243ff11dde681d24c8a7f4913c3d7a10b855bda47e8fb8ecad31e00d839705416be6f SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a
diff --git a/app-emulation/winetricks/winetricks-20240105.ebuild b/app-emulation/winetricks/winetricks-20240105.ebuild
new file mode 100644
index 000000000000..91fa5d31a9b7
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20240105.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+wtg="winetricks-gentoo-2012.11.24"
+
+SRC_URI="${SRC_URI}
+	gtk? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+	kde? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="https://github.com/Winetricks/winetricks https://wiki.winehq.org/Winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar test"
+RESTRICT="!test? ( test )"
+
+# dev-util/shellcheck is not available for x86
+RESTRICT+=" x86? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/bashate
+		dev-util/checkbashisms
+		|| (
+			dev-util/shellcheck-bin
+			dev-util/shellcheck
+		)
+	)
+"
+DEPEND=""
+RDEPEND="${DEPEND}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	net-misc/wget
+	virtual/wine
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )
+"
+
+# Test targets include syntax checks only, not the "heavy duty" tests
+# that would require a lot of disk space, as well as network access.
+
+# This uses a non-standard "Wine" category, which is provided by
+# '/etc/xdg/menus/applications-merged/wine.menu' from the
+# 'app-emulation/wine-desktop-common' package.
+# https://bugs.gentoo.org/451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+
+	else
+		default
+	fi
+}
+
+src_test() {
+	./tests/shell-checks || die "Test(s) failed."
+}
+
+src_install() {
+	default
+
+	if ! use gtk && ! use kde; then
+		rm -r "${ED}"/usr/share/applications || die
+		rm -r "${ED}"/usr/share/icons || die
+	fi
+}
diff --git a/app-emulation/winetricks/winetricks-99999999.ebuild b/app-emulation/winetricks/winetricks-99999999.ebuild
index 9085fdd239a9..91fa5d31a9b7 100644
--- a/app-emulation/winetricks/winetricks-99999999.ebuild
+++ b/app-emulation/winetricks/winetricks-99999999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8