app-misc/hivex: add 1.3.21

Bug: https://bugs.gentoo.org/829895
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 125 insertions, 0 deletions

diff --git a/app-misc/hivex/Manifest b/app-misc/hivex/Manifest
index 167ecfc75022..6f2fdea97f9e 100644
--- a/app-misc/hivex/Manifest
+++ b/app-misc/hivex/Manifest
@@ -1 +1,2 @@
 DIST hivex-1.3.20.tar.gz 1727498 BLAKE2B db6448242fc4b72d75cc7234a49e146cb165b1b9b9e2e72fb2a05be37cbb1d8ca865ccc51c4d2d50199e69cae2d870743ecd41534290e9a100bb268c2437ee22 SHA512 366e84c2a13ff53c70036df60db6e2b469cd06e3405761df73c47978b4fa0245246a1ea912aa5852b1272221d55c6c100b40b00e4c9a6f5668d12ff7f93c787a
+DIST hivex-1.3.21.tar.gz 1729723 BLAKE2B 16c5bad3f06e1293344c39f100596a466a93eb7db1c189bd59859434d7071102e10641bb820cf791834280c2ad79dba0df4efea9b8a84d02727bfdf13f7915d1 SHA512 e893d9fa77655540d29ef6657764f701f9cddb33d11b2bfef36ce0c2caebab92b55a32b7e1c99efbab0d53f558a44bf1c4c6f6da13daa37d568ff96d7d28f842
diff --git a/app-misc/hivex/hivex-1.3.21.ebuild b/app-misc/hivex/hivex-1.3.21.ebuild
new file mode 100644
index 000000000000..753f0cbb52ba
--- /dev/null
+++ b/app-misc/hivex/hivex-1.3.21.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+USE_RUBY="ruby26 ruby27"
+RUBY_OPTIONAL=yes
+PYTHON_COMPAT=( python3_{8..10} )
+inherit perl-module ruby-ng python-single-r1 strip-linguas
+
+DESCRIPTION="Library for reading and writing Windows Registry 'hive' binary files"
+HOMEPAGE="https://libguestfs.org"
+SRC_URI="https://libguestfs.org/download/${PN}/${P}.tar.gz"
+S="${WORKDIR}/${P}"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ocaml readline +perl python test ruby"
+
+RDEPEND="
+	dev-libs/libxml2:2
+	virtual/libiconv
+	virtual/libintl
+	ocaml? (
+		dev-lang/ocaml[ocamlopt]
+		dev-ml/findlib[ocamlopt]
+	 )
+	perl? (
+		dev-lang/perl:=
+		dev-perl/IO-stringy
+	)
+	python? ( ${PYTHON_DEPS} )
+	readline? ( sys-libs/readline:0 )
+	ruby? ( $(ruby_implementations_depend) )
+"
+DEPEND="${RDEPEND}
+	perl? (
+		test? (
+			dev-perl/Pod-Coverage
+			dev-perl/Test-Pod-Coverage
+		)
+	)"
+
+ruby_add_bdepend "ruby? ( dev-ruby/rake
+			virtual/rubygems
+			dev-ruby/rdoc )"
+ruby_add_rdepend "ruby? ( virtual/rubygems )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+			ruby? ( || ( $(ruby_get_use_targets) ) )"
+
+DOCS=( README )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	use ruby && ruby-ng_pkg_setup
+}
+
+src_unpack() {
+	default
+
+	cp -prlP "${WORKDIR}/${P}" "${WORKDIR}"/all || die
+}
+
+src_prepare() {
+	default
+
+	use perl && perl-module_src_prepare
+	use ruby && ruby-ng_src_prepare
+}
+
+src_configure() {
+	use ruby && ruby-ng_src_configure
+
+	if use perl; then
+		pushd perl || die
+		perl-module_src_configure
+		popd || die
+	fi
+
+	local myeconfargs=(
+		$(use_with readline)
+		$(use_enable ocaml)
+		$(use_enable perl)
+		--enable-nls
+		--disable-ruby
+		$(use_enable python)
+		--disable-rpath
+		--disable-static
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use ruby && ruby-ng_src_compile
+}
+
+src_install() {
+	strip-linguas -i po
+
+	emake install DESTDIR="${ED}" "LINGUAS=""${LINGUAS}"""
+
+	if use python; then
+		python_optimize
+	fi
+
+	if use ruby; then
+		ruby-ng_src_install
+	fi
+
+	if use perl; then
+		perl_delete_localpod
+
+		# Workaround Build.PL for now (see libguestfs too)
+		doman "${ED}"/usr/man/man3/*
+		rm -rf "${ED}"/usr/man || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+}