app-misc/fastfetch: add 1.12.1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 70bbdc0e41a1..737c21d81419 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1 +1,2 @@
 DIST fastfetch-1.12.0.tar.gz 537924 BLAKE2B f7d815890193c1ad30cd1d714b9d9a751124dd34a838c9b81e7ac05392082d54e7c658ea93ce2d7ca44d4b8bff9d4cb55ea1e958731eccf1db14a53bc04072b2 SHA512 8a9b63b7eda6002771fe3c5852b31acb337c1a78d382bee8f1caa13c02e24cff1728506af2295c231f02d6ffba8b3bf9772d4a7f7f70938e83d256e74cc14de1
+DIST fastfetch-1.12.1.tar.gz 537953 BLAKE2B 1304cfaf02599dbaafe76ed514e675a2e7f684493c9fc4aeab4982b21a6fe6226b0563395ab5a3afa366494ae0c45174f73c79c0cb831434fe820e8a76936bb6 SHA512 04cc98aaf4d22bb064ba9ce7986c1fe4988659cff87a5eb9245907a00a03d95d3e27b589fc5da48743ed476988da98da27bc02fd7cdd5f7f04519a2a637547aa
diff --git a/app-misc/fastfetch/fastfetch-1.12.1.ebuild b/app-misc/fastfetch/fastfetch-1.12.1.ebuild
new file mode 100644
index 000000000000..7a1c4c649c9a
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.12.1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus gnome imagemagick networkmanager opencl opengl osmesa pci pulseaudio sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_LIBCJSON=no
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}