app-portage/pfl: Revision bump.

Add Python 3.10 support. Bump to EAPI 8.

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Daniel Pielmeier <billie@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/app-portage/pfl/pfl-3.2-r1.ebuild b/app-portage/pfl/pfl-3.2-r1.ebuild
new file mode 100644
index 000000000000..28f10306a4f3
--- /dev/null
+++ b/app-portage/pfl/pfl-3.2-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{8,9,10} )
+PYTHON_REQ_USE="xml"
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="Searchable online file/package database for Gentoo"
+HOMEPAGE="http://www.portagefilelist.de https://github.com/portagefilelist/client"
+SRC_URI="https://github.com/portagefilelist/client/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="+network-cron"
+
+DEPEND=""
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/termcolor[${PYTHON_USEDEP}]
+	sys-apps/portage[${PYTHON_USEDEP}]
+	network-cron? ( sys-apps/util-linux[caps] )
+"
+
+S="${WORKDIR}/client-${PV}"
+
+python_install_all() {
+	if use network-cron ; then
+		exeinto /etc/cron.weekly
+		doexe cron/pfl
+	fi
+
+	systemd_dounit systemd/pfl.{service,timer}
+
+	keepdir /var/lib/${PN}
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if [[ ! -e "${EROOT}/var/lib/${PN}/pfl.info" ]]; then
+		touch "${EROOT}/var/lib/${PN}/pfl.info" || die
+	fi
+	chown -R portage:portage "${EROOT}/var/lib/${PN}" || die
+	chmod 775 "${EROOT}/var/lib/${PN}" || die
+}