dev-libs/girara: update EAPI 7 -> 8

Signed-off-by: Leonardo Hernández Hernández <leohdz172@proton.me>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 74 insertions, 11 deletions

diff --git a/dev-libs/girara/girara-0.4.0-r1.ebuild b/dev-libs/girara/girara-0.4.0-r1.ebuild
new file mode 100644
index 000000000000..34e5e35a0455
--- /dev/null
+++ b/dev-libs/girara/girara-0.4.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson virtualx
+
+DESCRIPTION="UI library that focuses on simplicity and minimalism"
+HOMEPAGE="https://pwmt.org/projects/girara/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
+	EGIT_BRANCH="develop"
+else
+	SRC_URI="https://pwmt.org/projects/girara/download/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+fi
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE="doc libnotify test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib:=
+	>=x11-libs/gtk+-3.20:3
+	libnotify? ( x11-libs/libnotify )
+"
+RDEPEND="${DEPEND}"
+# Tests are run under virtx
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/check
+		x11-libs/gtk+:3[X]
+	)
+"
+
+src_configure() {
+	local -a emesonargs=(
+		-Djson=enabled
+		$(meson_feature doc docs)
+		$(meson_feature libnotify notify)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# TODO: run test on wayland
+	virtx meson_src_test
+}
diff --git a/dev-libs/girara/girara-9999.ebuild b/dev-libs/girara/girara-9999.ebuild
index 88dc773e88de..47b80dd68548 100644
--- a/dev-libs/girara/girara-9999.ebuild
+++ b/dev-libs/girara/girara-9999.ebuild
@@ -1,14 +1,14 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit meson virtualx
 
 DESCRIPTION="UI library that focuses on simplicity and minimalism"
 HOMEPAGE="https://pwmt.org/projects/girara/"
 
-if [[ ${PV} == *999 ]]; then
+if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
 	EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
 	EGIT_BRANCH="develop"
@@ -23,24 +23,33 @@ IUSE="doc libnotify test"
 
 RESTRICT="!test? ( test )"
 
-DEPEND="dev-libs/glib:2
+DEPEND="
+	dev-libs/glib:2
 	dev-libs/json-glib:=
 	>=x11-libs/gtk+-3.20:3
-	libnotify? ( x11-libs/libnotify )"
+	libnotify? ( x11-libs/libnotify )
+"
 RDEPEND="${DEPEND}"
-BDEPEND="doc? ( app-doc/doxygen )
-	test? ( dev-libs/check )
-	virtual/pkgconfig"
+# Tests are run under virtx
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		dev-libs/check
+		x11-libs/gtk+:3[X]
+	)
+"
 
 src_configure() {
-	local emesonargs=(
+	local -a emesonargs=(
 		-Djson=enabled
-		-Ddocs=$(usex doc enabled disabled)
-		-Dnotify=$(usex libnotify enabled disabled)
+		$(meson_feature doc docs)
+		$(meson_feature libnotify notify)
 	)
 	meson_src_configure
 }
 
 src_test() {
+	# TODO: run test on wayland
 	virtx meson_src_test
 }