dev-libs/intel-compute-runtime: add 23.35.27191.9

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index 555223e44a94..fc31e09fb3e6 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1 +1,2 @@
 DIST intel-compute-runtime-23.22.26516.18.tar.gz 6695812 BLAKE2B c413d0ee70564292122d3eb125669ffc0a0dd7491ec208688055a71173b4112db6da96934cd16c91c4ff1a932cf8fdea490c5d849d98c7171bc916d6d77dc837 SHA512 5949866da0c3e48582636b9260e9ee6321c06db543a30e8567310add1b93a7b37ee3e4f35dcd5d9a6f611ed701daa52fac98ae2c11e26809f3fe7da84d289fc3
+DIST intel-compute-runtime-23.35.27191.9.tar.gz 6856146 BLAKE2B 02676adde05bef374f12ca6d6baac1a577ae32b712e77bf01e09d6cc01a2eeeb4d6eacc8fb302e350aca34f9d70f07a20ac70a52a682bdefb06223c4b6611cf7 SHA512 39abd4830ce379894bd9f17e2a1685b6403ddd13bae1fb1549c11de3e4b26536adfb24194c245466c45ba01c9d89c5d69bb60fbb498d9c23c24d31b018a37af8
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-23.35.27191.9.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.35.27191.9.ebuild
new file mode 100644
index 000000000000..5d8dd8c58fab
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.35.27191.9.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND=">=media-libs/gmmlib-22.3.5:="
+
+DEPEND="
+	${DEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-compiler-1.0.15136.4
+	>=dev-util/intel-graphics-system-controller-0.8.13:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.14.0:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}