dev-libs/intel-compute-runtime: add 23.09.25812.14

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/dev-libs/intel-compute-runtime/Manifest b/dev-libs/intel-compute-runtime/Manifest
index f8a6d2ceccd4..e1ea30e4f3ff 100644
--- a/dev-libs/intel-compute-runtime/Manifest
+++ b/dev-libs/intel-compute-runtime/Manifest
@@ -1,2 +1,3 @@
 DIST intel-compute-runtime-23.05.25593.11.tar.gz 6181361 BLAKE2B 4cab9f759bbcb10dd91776648d1e300f752f49f0ffcacfacf2519648b7c02b3dde1f04c4c6104896baf24cafcc9382406cd931e224f5a656718ec10629c74f80 SHA512 5bfef689dbb7c7ed2b500c4b040eed4ac43c5a5f418fb94125db51193d4269379fb1b2cd8c95e53a2e4024c3415455f2dd7a07e79b4bf84c27b29150c328627a
 DIST intel-compute-runtime-23.05.25593.18.tar.gz 6182150 BLAKE2B 81dcceb6d13e3dfbf5fb811faf406617dba7f83d908b94806b76df115b70a3906d8786ea8aaa1b92e963a0c97e843d13e10d7c4fd66885d309ce910c7ed18d56 SHA512 f249e51f78faee84e3bd253f1ea39fe06337939f54612f0f645e0e57319abe8449e1822291dbf1760e3805a60bdaad36c59df523859a5d879d39024138bc0907
+DIST intel-compute-runtime-23.09.25812.14.tar.gz 6264026 BLAKE2B a346ee4b12a774532bb1e716159e8256001ef933b7e5943752d3eccc046a3a95b84b1b6679d81771653cab7182f51bf64cb9443da8a0cb38fea2cfd3d7ab620a SHA512 4e42b1ae8ee2f7b21e35d37d15339d18dc871f27ca759c97104f7987688193a62eabd07107cf337679a28341eb71119c5e3edc40ec48a1997a2ddbd213ba02ea
diff --git a/dev-libs/intel-compute-runtime/intel-compute-runtime-23.09.25812.14.ebuild b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.09.25812.14.ebuild
new file mode 100644
index 000000000000..f25d8d52a81a
--- /dev/null
+++ b/dev-libs/intel-compute-runtime/intel-compute-runtime-23.09.25812.14.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release"
+MY_PN="${PN/intel-/}"
+MY_P="${MY_PN}-${PV}"
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Intel Graphics Compute Runtime for oneAPI Level Zero and OpenCL Driver"
+HOMEPAGE="https://github.com/intel/compute-runtime"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+l0 +vaapi"
+
+RDEPEND=">=media-libs/gmmlib-22.1.7:="
+
+DEPEND="
+	${DEPEND}
+	dev-libs/intel-metrics-discovery:=
+	dev-libs/intel-metrics-library:=
+	dev-libs/libnl:3
+	dev-libs/libxml2:2
+	>=dev-util/intel-graphics-compiler-1.0.12812.26
+	>=dev-util/intel-graphics-system-controller-0.8.7:=
+	media-libs/mesa
+	>=virtual/opencl-3
+	l0? ( >=dev-libs/level-zero-1.10.0:= )
+	vaapi? (
+		x11-libs/libdrm[video_cards_intel]
+		media-libs/libva
+	)
+"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( "README.md" "FAQ.md" )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.24.23453-remove-fortify-sources.patch"
+)
+
+src_prepare() {
+	# Remove '-Werror' from default
+	sed -e '/Werror/d' -i CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# See https://github.com/intel/compute-runtime/issues/531
+	filter-lto
+
+	local mycmakeargs=(
+		-DCCACHE_ALLOWED="OFF"
+		-DCMAKE_INSTALL_PREFIX="${EPREFIX}/usr"
+		-DCMAKE_INSTALL_LIBDIR="$(get_libdir)"
+		-DBUILD_WITH_L0="$(usex l0)"
+		-DDISABLE_LIBVA="$(usex !vaapi)"
+		-DNEO__METRICS_LIBRARY_INCLUDE_DIR="${ESYSROOT}/usr/include"
+		-DKHRONOS_GL_HEADERS_DIR="${ESYSROOT}/usr/include"
+		-DOCL_ICD_VENDORDIR="${EPREFIX}/etc/OpenCL/vendors"
+		-DSUPPORT_DG1="ON"
+		-Wno-dev
+
+		# See https://github.com/intel/intel-graphics-compiler/issues/204
+		# -DNEO_DISABLE_BUILTINS_COMPILATION="ON"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DSKIP_UNIT_TESTS="1"
+	)
+
+	cmake_src_configure
+}