*/*: do not source gentoo-helpers.sh in netsurf libraries

This commit changes several ebuilds to use eclass netsurf instead of
sourcing /usr/share/netsurf-buildsystem/gentoo-helpers.sh

This also fixes building these packages in a prefix.

This commit changes following packages:

dev-libs/libcss
dev-libs/libnsfb
dev-libs/libnsutils
dev-libs/libparserutils
dev-libs/libwapcaplet
dev-libs/nsgenbind
media-libs/libnsbmp
media-libs/libnsgif
media-libs/libnspsl
media-libs/librosprite
media-libs/libsvgtiny
net-libs/libdom
net-libs/libhubbub
www-client/netsurf

Signed-off-by: Lukas Vacek <lucas.vacek@gmail.com>
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-libs/libcss/libcss-0.8.0-r2.ebuild b/dev-libs/libcss/libcss-0.8.0-r2.ebuild
new file mode 100644
index 000000000000..b388f262e7d5
--- /dev/null
+++ b/dev-libs/libcss/libcss-0.8.0-r2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit netsurf
+
+DESCRIPTION="CSS parser and selection engine, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/libcss/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~m68k-mint"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/libparserutils-0.2.1-r1
+	>=dev-libs/libwapcaplet-0.4.0"
+DEPEND="${RDEPEND}
+	>=dev-util/netsurf-buildsystem-1.7-r1
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+src_prepare() {
+	default
+	sed -e '1i#pragma GCC diagnostic ignored "-Wimplicit-fallthrough"' \
+		-i src/parse/parse.c src/select/arena_hash.h || die
+	sed -e '1i#pragma GCC diagnostic ignored "-Wmaybe-uninitialized"' \
+		-i src/parse/parse.c src/select/computed.c || die
+}
+
+_emake() {
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${D}" install
+}