dev-ml/opam-core: 2.1.2 bump

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 46 insertions, 0 deletions

diff --git a/dev-ml/opam-core/opam-core-2.1.2.ebuild b/dev-ml/opam-core/opam-core-2.1.2.ebuild
new file mode 100644
index 000000000000..fb6df20a60b1
--- /dev/null
+++ b/dev-ml/opam-core/opam-core-2.1.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# We are opam
+OPAM_INSTALLER_DEP=" "
+inherit opam
+
+DESCRIPTION="Core libraries for opam"
+HOMEPAGE="https://opam.ocaml.org/ https://github.com/ocaml/opam"
+SRC_URI="https://github.com/ocaml/opam/archive/${PV/_/-}.tar.gz -> opam-${PV}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/dev-ml/opam/opam-2.1.0-dose3-6.patch.xz"
+S="${WORKDIR}/opam-${PV}"
+OPAM_INSTALLER="${S}/opam-installer"
+
+LICENSE="LGPL-2.1"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	dev-ml/ocamlgraph:=
+	dev-ml/re:=
+	dev-ml/opam-file-format:=
+	dev-ml/cmdliner:=
+"
+DEPEND="${RDEPEND}
+	dev-ml/cppo"
+
+PATCHES=( "${WORKDIR}"/opam-2.1.0-dose3-6.patch )
+
+src_prepare() {
+	default
+	cat <<- EOF >> "${S}/dune"
+		(env
+		 (dev
+		  (flags (:standard -warn-error -3-9)))
+		 (release
+		  (flags (:standard -warn-error -3-9))))
+	EOF
+}
+
+src_compile() {
+	emake -j1 opam-installer
+	emake -j1 ${PN}.install
+}