dev-python/openstacksdk: Bump to 0.103.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 7263f9e40ea7..8c33fe798eef 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1 +1,2 @@
 DIST openstacksdk-0.102.0.tar.gz 1083232 BLAKE2B 30be836257fd63d6f2f3c3ad8d55af4261e5fe882f1597a442534d65aa3763eba693b4df393f359cdb239fd5da620aa712472be883e406bdf5d70bd73c257683 SHA512 34aaa0b85977c47a3b03988ccbc1d156d35600e893e0f59f8fe02a1fda4bf9fcebcb4d6b765efe5a2acfd0d9c03eb7954ef1917a0a5696196cc8484ef2865958
+DIST openstacksdk-0.103.0.tar.gz 1094619 BLAKE2B 66b4375469b2a8a48640198f94fa6d893c3f5d0e93a20f00dee868d6ed2da34fe367ec885691a06f9b4c056092837b5dd1033201922cb909fc7124456c7b6369 SHA512 175166fbf0aa851ff51c86b99d10cf30da6fe7c516e2d6020061fdcc9627f7d4630e3cc9ef3699be52cf298088f2f80240061e6a851a13effbd13d359a6dab26
diff --git a/dev-python/openstacksdk/openstacksdk-0.103.0.ebuild b/dev-python/openstacksdk/openstacksdk-0.103.0.ebuild
new file mode 100644
index 000000000000..3a76155d34cb
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-0.103.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack"
+HOMEPAGE="
+	https://opendev.org/openstack/openstacksdk/
+	https://github.com/openstack/openstacksdk/
+	https://pypi.org/project/openstacksdk/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/munch-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# requires hacking
+	rm openstack/tests/unit/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}