dev-python/pygame: Bump to 2.0.0 final

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 92 insertions, 0 deletions

diff --git a/dev-python/pygame/Manifest b/dev-python/pygame/Manifest
index e262a8fbf4a9..fad79bf4293a 100644
--- a/dev-python/pygame/Manifest
+++ b/dev-python/pygame/Manifest
@@ -3,3 +3,4 @@ DIST pygame-2.0.0.dev10.tar.gz 5567274 BLAKE2B 7d78f260318cfabeb33f1073ae210f890
 DIST pygame-2.0.0.dev18.tar.gz 5591175 BLAKE2B 3479e9161e4dc5f00123f359b29f5c133020578bd09fc972f3f2d9e55b1700f4ac5eccc904524e98fe827fa7ed871db130da1f7b9aa8a67da98f42562f2ee766 SHA512 dfa8ac023e5da1688825281dd06e22aa59fa7061dcf17b8ec1c8c84b2bda7e27d39a97be3375d9ccb15aa50a0096be74ef6c80614e5d71729157712463140af1
 DIST pygame-2.0.0.dev22.tar.gz 5596946 BLAKE2B 788a2e328d456198b032226f10b7d0686b7e862bf0106334ed3e26150ece43a1a9a9cbdc4f72f33e27d52e9f7c5e063292170eba9c07213474ecaf295280185a SHA512 2809f101dce256143a57f5b47aac2ceb3c2646301179c37e7545672784a7f8dfd74565d1f6a45c394f59bcfcef4a52473160bf94b494db79a982490a7ac19fd8
 DIST pygame-2.0.0.dev24.tar.gz 5598687 BLAKE2B d46ea0112f5a47c9721e16d26d42ef7088a498a9136577a4348271f269a1f4622ba7746efd71fe20b3930e46bbeb2569b9b650511b9a682f9ea688793493bdf7 SHA512 d75b3f49bdaee9b409acf2a075c068cb8d50e5e8e7101f5b79e2abd3db4d09b9eee5c9027177cabf6b71b5dab7f6c412c77caa535c28369e46e347f5c516d59f
+DIST pygame-2.0.0.tar.gz 5522621 BLAKE2B 49773979af53595d3ff2db1a18e4bcd217e26db3ec28d6129d2a588f23a1bd5326fa79fab32c25aa796738cde0e68f5741bee58f62432e86f89cd49ee17a8f14 SHA512 3f65924d0e1d2863b84118a4e468b521a289e2cf174405c6f3ee2b2a2ed399cde7f9f310d57c4166351f84caaea02dd7408ee852dbcee7c205bb2955b6078fda
diff --git a/dev-python/pygame/pygame-2.0.0.ebuild b/dev-python/pygame/pygame-2.0.0.ebuild
new file mode 100644
index 000000000000..a43bd4b42236
--- /dev/null
+++ b/dev-python/pygame/pygame-2.0.0.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6..9} )
+
+inherit distutils-r1
+
+MY_PV=${PV/_pre/.dev}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python bindings for SDL multimedia library"
+HOMEPAGE="https://www.pygame.org/"
+SRC_URI="
+	https://github.com/pygame/pygame/releases/download/${MY_PV}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc examples midi opengl test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	media-libs/freetype
+	>=media-libs/sdl2-image-1.2.2
+	>=media-libs/sdl2-mixer-1.2.4
+	>=media-libs/sdl2-ttf-2.0.6
+	>=media-libs/smpeg2-0.4.4-r1
+	midi? ( media-libs/portmidi )
+	X? ( >=media-libs/libsdl2-1.2.5[opengl?,threads,video,X] )
+	!X? ( >=media-libs/libsdl2-1.2.5[threads] )"
+DEPEND="${RDEPEND}
+	test? (
+		media-libs/sdl2-image[gif,jpeg,png]
+		media-libs/sdl2-mixer[mp3,vorbis,wav]
+	)"
+# fontconfig used for fc-list
+RDEPEND+="
+	media-libs/fontconfig"
+# util-linux provides script
+BDEPEND="
+	test? (
+		media-libs/fontconfig
+		sys-apps/util-linux
+	)"
+
+src_prepare() {
+	if ! use midi; then
+		rm test/midi_test.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	PORTMIDI_INC_PORTTIME=1 LOCALBASE="${EPREFIX}/usr" \
+		"${EPYTHON}" "${S}"/buildconfig/config.py -auto || die
+
+	# Disable automagic dependency on PortMidi.
+	if ! use midi; then
+		sed -e "s:^pypm :#&:" -i Setup || die "sed failed"
+	fi
+}
+
+python_test() {
+	local -x PYTHONPATH=${BUILD_DIR}/install/lib
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=disk
+	esetup.py install \
+		--root="${BUILD_DIR}"/install \
+		--install-lib=lib
+	script -eqc "${EPYTHON} -m pygame.tests" || die
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Bug #497720
+	rm -fr "${D}"$(python_get_sitedir)/pygame/{docs,examples,tests}/ || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		docinto html
+		dodoc -r docs/*
+	fi
+
+	use examples && dodoc -r examples
+}