dev-python/pytables: 3.4.4 version bump

Closes: https://bugs.gentoo.org/668472
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>

1 files changed, 78 insertions, 0 deletions

diff --git a/dev-python/pytables/pytables-3.4.4.ebuild b/dev-python/pytables/pytables-3.4.4.ebuild
new file mode 100644
index 000000000000..2dbdcf0375b4
--- /dev/null
+++ b/dev-python/pytables/pytables-3.4.4.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+MY_PN=tables
+MY_P=${MY_PN}-${PV}
+
+inherit distutils-r1
+
+DESCRIPTION="Hierarchical datasets for Python"
+HOMEPAGE="https://www.pytables.org/"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="BSD"
+IUSE="doc examples"
+
+RDEPEND="
+	app-arch/bzip2:0=
+	app-arch/lz4:0=
+	>=app-arch/zstd-1.0.0:=
+	>=dev-libs/c-blosc-1.11.1:0=
+	dev-libs/lzo:2=
+	>=dev-python/numpy-1.8.1[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.5.2[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=sci-libs/hdf5-1.8.15:0=
+"
+DEPEND="${RDEPEND}
+	>=dev-python/cython-0.21[${PYTHON_USEDEP}]
+"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( ANNOUNCE.txt RELEASE_NOTES.txt THANKS )
+
+python_prepare_all() {
+	export HDF5_DIR="${EPREFIX}"/usr
+	rm tables/*.c || die
+	sed -e "s:/usr:${EPREFIX}/usr:g" \
+		-i setup.py || die
+	rm -r c-blosc/{blosc,internal-complibs} || die
+	sed -i -e '/_version/ s/\\s\*/\\s\+/' setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local -x CFLAGS="${CFLAGS}"
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	${EPYTHON} tables/tests/test_all.py || die
+}
+
+python_install_all() {
+	if use doc; then
+		HTML_DOCS=( doc/html/. )
+		DOCS+=( doc/scripts )
+	fi
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		dodoc -r contrib
+		docompress -x /usr/share/doc/${PF}/examples
+		docompress -x /usr/share/doc/${PF}/contrib
+	fi
+}