dev-python/pyxattr: Bump to version 0.6.0

Package-Manager: Portage-2.3.3, Repoman-2.3.1

2 files changed, 57 insertions, 0 deletions

diff --git a/dev-python/pyxattr/Manifest b/dev-python/pyxattr/Manifest
index 3a777bc01298..930b800efa76 100644
--- a/dev-python/pyxattr/Manifest
+++ b/dev-python/pyxattr/Manifest
@@ -1,2 +1,3 @@
 DIST pyxattr-0.5.3.tar.gz 25977 SHA256 c395b34707506aa4e74da4930efaec9bb84bd652d8459de5b603bb8dc8b1d585 SHA512 ac1aa227ab9980e0b05bf71ac4466e8747791a0d5ea30d404359526ca32e6846ad9d4ef72208ff9c7a8208d91ffa309feebe7eab818ef2dc3ae1a5e9414ffeaa WHIRLPOOL 905076e9917d8eb8f78a564d31dfe7c649cd459106513dea53985eb026a144dfbaf062992786f63b799ec7410eec9dbc3f4ae9c41cbb7e1ec61f769c81fa6898
 DIST pyxattr-0.5.5.tar.gz 26718 SHA256 132297c35261dd74b2ae2bd558e725b04834bbdf60997495e0110e255f5f2a3f SHA512 77b732a7e524a7c31a0511df2c96c18b214f93c6ac47276ecdf12ed95133ee506fa882b2532a7159aa2f4e02a7128e33bb8883ea632a5394297d98fb28898327 WHIRLPOOL 42db6c0d603f5bfca951a39194e5b95d4285a68b4c5e3f77ffe806fb5f05e46ce2f12dadc2d598c40178b68b83ee947b50474c7c026dc8e40378fc9c552a5180
+DIST pyxattr-0.6.0.tar.gz 31057 SHA256 09d00ee4235841a5d7d6275837c5cfc37a8b68efdd663f588505fff5a8c46ea8 SHA512 c56bf57729b5f8c8e3e19e29fd903b7365c6644abe3dcebf57ffc2f97a1e92d0e22cdc0a967c5abee3a74ba61a2a379e31a1734f45449095bdb7895b8357a9bb WHIRLPOOL aa312257d527a890c0aea65317d11ad0b6065b28aea18cc84f181cd1476de8cd31bf14af9c60bb0804a37283985830655c4d5ae9c16faec099572fb067c306f7
diff --git a/dev-python/pyxattr/pyxattr-0.6.0.ebuild b/dev-python/pyxattr/pyxattr-0.6.0.ebuild
new file mode 100644
index 000000000000..34a27cb5d275
--- /dev/null
+++ b/dev-python/pyxattr/pyxattr-0.6.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="Python interface to xattr"
+HOMEPAGE="http://pyxattr.k1024.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	http://pyxattr.k1024.org/downloads/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="sys-apps/attr"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( >=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+python_prepare_all() {
+	sed -i -e 's:, "-Werror"::' setup.py || die
+	# Bug 548486
+	sed -e "s:html_theme = 'default':html_theme = 'classic':" \
+		-i doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake doc
+}
+
+src_test() {
+	# Perform the tests in /var/tmp; that location is more likely
+	# to have xattr support than /tmp which is often tmpfs.
+	export TESTDIR=/var/tmp
+
+	einfo 'Please note that the tests fail if xattrs are not supported'
+	einfo 'by the filesystem used for /var/tmp.'
+	distutils-r1_src_test
+}
+
+python_test() {
+	nosetests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	distutils-r1_python_install_all
+}