proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 61 insertions, 0 deletions

diff --git a/dev-python/webhelpers/webhelpers-1.3-r1.ebuild b/dev-python/webhelpers/webhelpers-1.3-r1.ebuild
new file mode 100644
index 000000000000..8f3b4a5b6dce
--- /dev/null
+++ b/dev-python/webhelpers/webhelpers-1.3-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+MY_PN="WebHelpers"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Web Helpers"
+HOMEPAGE="http://webhelpers.groovie.org/ http://pypi.python.org/pypi/WebHelpers"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]
+	dev-python/webob[${PYTHON_USEDEP}]
+	dev-python/routes[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_prepare_all() {
+	# https://bitbucket.org/bbangert/webhelpers/issue/67
+	sed \
+		-e '/import datetime/a import os' \
+		-e 's:"/tmp/feed":os.environ.get("TMPDIR", "/tmp") + "/feed":' \
+		-i tests/test_feedgenerator.py || die "sed failed"
+
+	epatch "${FILESDIR}"/mime9ad434b.patch
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake html -C docs
+}
+
+python_test() {
+	nosetests || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		pushd docs/_build/html > /dev/null
+		docinto html
+		insinto /usr/share/doc/${PF}/html
+		doins -r [a-z]* _static || die "Installation of documentation failed"
+		popd > /dev/null
+	fi
+	distutils-r1_python_install_all
+}