dev-python/redis: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 0 insertions, 106 deletions

diff --git a/dev-python/redis/Manifest b/dev-python/redis/Manifest
index 14611da52d5b..e0a324020663 100644
--- a/dev-python/redis/Manifest
+++ b/dev-python/redis/Manifest
@@ -1,2 +1 @@
-DIST redis-py-5.0.0.gh.tar.gz 4767898 BLAKE2B 0dc1fcafe7ad82c00bf634e19b5afb7201f39dfd26dfcce398fbc40cff79fe03d3e2ecc2acccebf1405700fb72fc5894ce1b8438b55e6c10d52ec08124da50cb SHA512 24133be64b73a58edd7b0361a8b168b67f0e783576aaf0007f4b4b8d6032a227d6ebc7319c89fc323fc72ef1063e4a899d9a8be9eaa833d347345a59a65fff31
 DIST redis-py-5.0.1.gh.tar.gz 4769633 BLAKE2B 3b572ef41abfdb0cf0ba957c93a23aacbe931e50ebe11e50a62dffe6aaaf57926224f7a497727e1e233b443c6be053f786dadac64f16a5170748e6afd9604d01 SHA512 05c32d6961326ff39312f5513136e72be3a42819b0c4bf646f3bac14e66a8a87a191697a89c2cbc22a83398896e25adc5fbd34f12e67719f0a0af927bf423130
diff --git a/dev-python/redis/redis-5.0.0.ebuild b/dev-python/redis/redis-5.0.0.ebuild
deleted file mode 100644
index 773b415b4d2f..000000000000
--- a/dev-python/redis/redis-5.0.0.ebuild
+++ /dev/null
@@ -1,105 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} pypy3 )
-
-inherit distutils-r1
-
-MY_P=redis-py-${PV}
-DESCRIPTION="Python client for Redis key-value store"
-HOMEPAGE="
-	https://github.com/redis/redis-py/
-	https://pypi.org/project/redis/
-"
-SRC_URI="
-	https://github.com/redis/redis-py/archive/v${PV}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~riscv ~sparc x86"
-
-RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/async-timeout-4.0.2[${PYTHON_USEDEP}]
-	' 3.{9..10})
-"
-BDEPEND="
-	test? (
-		dev-db/redis
-		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
-		dev-python/pytest-timeout[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Flaky test
-		tests/test_pubsub.py::TestPubSubDeadlock::test_pubsub_deadlock
-		# require extra redis modules that apparently aren't packaged
-		# on Gentoo
-		tests/test_bloom.py
-		tests/test_graph.py
-		tests/test_json.py
-		tests/test_timeseries.py
-		# apparently available only in "Redis Stack 7.2 RC3 or later"
-		tests/test_commands.py::TestRedisCommands::test_tfunction_load_delete
-		tests/test_commands.py::TestRedisCommands::test_tfunction_list
-		tests/test_commands.py::TestRedisCommands::test_tfcall
-		# TODO
-		tests/test_commands.py::TestRedisCommands::test_zrank_withscore
-		tests/test_commands.py::TestRedisCommands::test_zrevrank_withscore
-		tests/test_commands.py::TestRedisCommands::test_xinfo_consumers
-		tests/test_asyncio/test_commands.py::TestRedisCommands::test_zrank_withscore
-		tests/test_asyncio/test_commands.py::TestRedisCommands::test_zrevrank_withscore
-		tests/test_asyncio/test_commands.py::TestRedisCommands::test_xinfo_consumers
-	)
-
-	case ${EPYTHON} in
-		python3.12)
-			EPYTEST_DESELECT+=(
-				tests/test_asyncio/test_connect.py
-				tests/test_asyncio/test_cwe_404.py
-			)
-			;;
-	esac
-
-	# TODO: try to run more servers?
-	epytest -m "not redismod and not onlycluster and not replica and not ssl"
-}
-
-src_test() {
-	local redis_pid="${T}"/redis.pid
-	local redis_port=6379
-
-	if has_version ">=dev-db/redis-7"; then
-		local extra_conf="
-			enable-debug-command yes
-			enable-module-command yes
-		"
-	fi
-
-	# Spawn Redis itself for testing purposes
-	einfo "Spawning Redis"
-	einfo "NOTE: Port ${redis_port} must be free"
-	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start redis server"
-		daemonize yes
-		pidfile ${redis_pid}
-		port ${redis_port}
-		bind 127.0.0.1 ::1
-		${extra_conf}
-	EOF
-
-	# Run the tests
-	distutils-r1_src_test
-
-	# Clean up afterwards
-	kill "$(<"${redis_pid}")" || die
-}