dev-python/requests-mock: bump to 1.5.2, add Python 3.7

Package-Manager: Portage-2.3.43, Repoman-2.3.10

2 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/requests-mock/Manifest b/dev-python/requests-mock/Manifest
index df3985d31b8c..8822b19bf452 100644
--- a/dev-python/requests-mock/Manifest
+++ b/dev-python/requests-mock/Manifest
@@ -1,2 +1,3 @@
 DIST requests-mock-1.2.0.tar.gz 40219 BLAKE2B b5ded6c97d920bab0c610c1be1c80f299e56cccd393c824b5c9ab3e0c298491b8be0b285c440bc8ba32eb1eec2eca14ec363d0f188c5b095192a56d01383c322 SHA512 ed24d1809aef597219ae2b0b376156a0760040795ccd660ee38f84cd1ceed58cbc5009764d7a365d31f941ee16e2b537b92ddcff92bcd8d47b7e95c67dc8d82c
 DIST requests-mock-1.5.0.tar.gz 47824 BLAKE2B 90d540e2372430c70b0ada0bc48a3a8085452e062e9ab57a232d080df8312c2a722c01d61fb399fe2a6bc31a2d6d61914d8d0e2c912a2e439062b27bb31914cf SHA512 21838017ac4d3066e2240b40b27bbe16f3bd989f37eba90f0a0d0cdb997e7e65c6d9dc63b31f64daaa6146cc3c6bccbba86382eda3f2ca72eb7cc8381969af36
+DIST requests-mock-1.5.2.tar.gz 47581 BLAKE2B 46beefc45e01355939a76b85e43a5b57cb1a870666eab7f610cad3e8a04a17da6a0864f9776a0f09028c847e8a4f7d0d2389a36f9a0431ed733a364d0f712c0b SHA512 206c91e892df84e38dcdf1264559128cfece76be2ce43b9c98238dfd438795d8c4ce3fcd43feb30246fbfca2d78832a23430ce1c9d3a7dc6e4417df5d65a8d3c
diff --git a/dev-python/requests-mock/requests-mock-1.5.2.ebuild b/dev-python/requests-mock/requests-mock-1.5.2.ebuild
new file mode 100644
index 000000000000..5c4420858b1f
--- /dev/null
+++ b/dev-python/requests-mock/requests-mock-1.5.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6,7}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mock out responses from the requests package"
+HOMEPAGE="https://github.com/jamielennox/requests-mock"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/pbr-0.8[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/subunit[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="
+	>=dev-python/requests-1.1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	# Disable reno which only works inside a git repository
+	# Disable intersphinx
+	sed -i -e "s/'reno.sphinxext',//" \
+		-e "s/'sphinx.ext.intersphinx'//" \
+		doc/source/conf.py || die
+	# Remove the release notes section which requires reno
+	rm doc/source/release-notes.rst || die
+	sed -i '/^=============$/,/release-notes/d' doc/source/index.rst || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build doc/source docs/source/build/_html || die
+		HTML_DOCS=( docs/source/build/_html/. )
+	fi
+}
+
+python_test() {
+	rm -rf .testrepository \
+		|| die "couldn't remove '.testrepository' under ${EPYTHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}