dev-ruby/gettext-setup: loosen gettext dependency

This got restricted upstream to keep support for ruby24,
but we no longer support that version and this restriction
is causing issues for other packages.

Closes: https://bugs.gentoo.org/733276
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Hans de Graaff <graaff@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-ruby/gettext-setup/gettext-setup-0.34-r2.ebuild b/dev-ruby/gettext-setup/gettext-setup-0.34-r2.ebuild
new file mode 100644
index 000000000000..ee59e09ee553
--- /dev/null
+++ b/dev-ruby/gettext-setup/gettext-setup-0.34-r2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A gem to ease i18n"
+HOMEPAGE="https://github.com/puppetlabs/gettext-setup-gem"
+SRC_URI="https://github.com/puppetlabs/gettext-setup-gem/archive/${PV}.tar.gz -> ${P}.tar.gz"
+RUBY_S="${PN}-gem-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND+=" dev-vcs/git"
+DEPEND+=" test? ( dev-vcs/git )"
+
+ruby_add_rdepend "
+	>=dev-ruby/fast_gettext-1.1.0:0
+	>=dev-ruby/ruby-gettext-3.0.2
+	dev-ruby/locale
+"
+
+all_ruby_prepare() {
+	sed -i -e 's/1.1.0/1.1/' \
+		-e "/'gettext'/ s/, '< 3.3.0'//" \
+		-e "s/spec.version.*$/spec.version = '${PV}'/" ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	sed -i -e '/simplecov/,/^end/ s:^:#: ; 1irequire "date"' spec/spec_helper.rb || die
+
+	# Avoid spec with specific locale requirements
+	sed -i -e '/can clear the locale/,/^    end/ s:^:#:' spec/lib/gettext-setup/gettext_setup_spec.rb || die
+}