dev-scheme/guile-gi: new package; add version 0.3.1 and live

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@gentoo.org>

4 files changed, 134 insertions, 0 deletions

diff --git a/dev-scheme/guile-gi/Manifest b/dev-scheme/guile-gi/Manifest
new file mode 100644
index 000000000000..073a4bf2c745
--- /dev/null
+++ b/dev-scheme/guile-gi/Manifest
@@ -0,0 +1 @@
+DIST guile-gi-0.3.1.tar.gz 345440 BLAKE2B 17c4ecda48951244d427098767072621278750614919f13d1b03b7ecda5f06b2274c7db50c4288b4bfe581cd852e80cd1d4137b5ccc0e18d0e23866e1eba323a SHA512 b866df95946069cad606bc8f7e7c988665029482bcb986109d652728023151a5e60ee39e86635b9f0b9f0d4d3a9cd72f39b65ee983438f71dff186994e3af197
diff --git a/dev-scheme/guile-gi/guile-gi-0.3.1.ebuild b/dev-scheme/guile-gi/guile-gi-0.3.1.ebuild
new file mode 100644
index 000000000000..0fd9d6ec4efe
--- /dev/null
+++ b/dev-scheme/guile-gi/guile-gi-0.3.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Bindings for GObject Introspection and libgirepository for Guile"
+HOMEPAGE="https://spk121.github.io/guile-gi/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/spk121/${PN}.git"
+else
+	SRC_URI="https://github.com/spk121/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+# Tests fail
+RESTRICT="strip test"
+LICENSE="GPL-3"
+SLOT="0"
+
+BDEPEND="
+	sys-apps/texinfo
+"
+DEPEND="
+	>=dev-scheme/guile-2.0.9:=
+	dev-libs/gobject-introspection
+	x11-libs/gtk+:3[introspection]
+"
+RDEPEND="${DEPEND}"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-introspection="yes"
+}
+
+src_install() {
+	default
+
+	mv "${D}/usr/share/doc/${PN}" "${D}/usr/share/doc/${PF}" || die
+}
diff --git a/dev-scheme/guile-gi/guile-gi-9999.ebuild b/dev-scheme/guile-gi/guile-gi-9999.ebuild
new file mode 100644
index 000000000000..0fd9d6ec4efe
--- /dev/null
+++ b/dev-scheme/guile-gi/guile-gi-9999.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Bindings for GObject Introspection and libgirepository for Guile"
+HOMEPAGE="https://spk121.github.io/guile-gi/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/spk121/${PN}.git"
+else
+	SRC_URI="https://github.com/spk121/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+# Tests fail
+RESTRICT="strip test"
+LICENSE="GPL-3"
+SLOT="0"
+
+BDEPEND="
+	sys-apps/texinfo
+"
+DEPEND="
+	>=dev-scheme/guile-2.0.9:=
+	dev-libs/gobject-introspection
+	x11-libs/gtk+:3[introspection]
+"
+RDEPEND="${DEPEND}"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --enable-introspection="yes"
+}
+
+src_install() {
+	default
+
+	mv "${D}/usr/share/doc/${PN}" "${D}/usr/share/doc/${PF}" || die
+}
diff --git a/dev-scheme/guile-gi/metadata.xml b/dev-scheme/guile-gi/metadata.xml
new file mode 100644
index 000000000000..1817ffcfd32d
--- /dev/null
+++ b/dev-scheme/guile-gi/metadata.xml
@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>scheme@gentoo.org</email>
+    <name>Gentoo Scheme Project</name>
+  </maintainer>
+  <longdescription lang="en">
+    This is a library for GNU Guile to create language bindings via GObject
+    Introspection.
+    Guile GI has two primary components:
+    - The gi scheme modules: guile modules that provide functionality to
+    dynamically generate Scheme API from GObject typelib files.
+    - libguile-gi.so or libguile-gi.dll: a compiled module that contains glue
+    code to interface with GObject.
+    To create bindings, use the use-typelibs syntax found in the (gi) library.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://github.com/spk121/guile-gi/issues/</bugs-to>
+    <remote-id type="github">spk121/guile-gi</remote-id>
+  </upstream>
+</pkgmetadata>