dev-util/aruba: add ruby25 revision

Package-Manager: Portage-2.3.36, Repoman-2.3.9

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-util/aruba/aruba-0.6.2-r2.ebuild b/dev-util/aruba/aruba-0.6.2-r2.ebuild
new file mode 100644
index 000000000000..ad124494699c
--- /dev/null
+++ b/dev-util/aruba/aruba-0.6.2-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+USE_RUBY="ruby23 ruby24 ruby25"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_RECIPE_TEST="cucumber"
+RUBY_FAKEGEM_EXTRADOC="History.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="aruba.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Cucumber steps for driving out command line applications"
+HOMEPAGE="https://github.com/cucumber/aruba"
+LICENSE="MIT"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~sparc ~x86"
+SLOT="0"
+IUSE=""
+
+DEPEND="${DEPEND} test? ( sys-devel/bc )"
+RDEPEND="${RDEPEND}"
+
+ruby_add_rdepend "
+	>=dev-ruby/childprocess-0.3.6
+	>=dev-ruby/rspec-expectations-2.7:2
+	>=dev-util/cucumber-1.1.1"
+
+ruby_add_bdepend "test? ( >=dev-ruby/rspec-2.11:2 >=dev-ruby/bcat-0.6.1 )"
+
+all_ruby_prepare() {
+	# Remove bundler-related code.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+	rm Gemfile || die
+
+	# Remove references to git ls-files.
+	sed -i -e '/git ls-files/d' aruba.gemspec || die
+}