games-action/super-hexagon: Bump to 20160217, EAPI 6, no bundling

This previously bundled SDL 2, probably because it wasn't packaged
when this was first added. With that unbundled, there are far fewer
dependencies and this makes unbundling everything less likely to
break. SDL is particularly stable in this regard. Because of this and
in the interests of security, I have dropped the bundled-libs
flag. Anyone experiencing issues can obviously file a bug report.

Closes: https://bugs.gentoo.org/611282
Package-Manager: Portage-2.3.24, Repoman-2.3.6

1 files changed, 60 insertions, 0 deletions

diff --git a/games-action/super-hexagon/super-hexagon-20160217.ebuild b/games-action/super-hexagon/super-hexagon-20160217.ebuild
new file mode 100644
index 000000000000..dbcff6cb6887
--- /dev/null
+++ b/games-action/super-hexagon/super-hexagon-20160217.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop eutils gnome2-utils unpacker
+
+TIMESTAMP="${PV:4:2}${PV:6:2}${PV:0:4}"
+DESCRIPTION="A minimal action game by Terry Cavanagh, with music by Chipzel"
+HOMEPAGE="http://www.superhexagon.com/"
+SRC_URI="superhexagon-${TIMESTAMP}-bin"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+RESTRICT="bindist fetch splitdebug"
+
+MYGAMEDIR="/opt/${PN}"
+QA_PREBUILT="${MYGAMEDIR#/}/superhexagon"
+
+DEPEND="app-arch/unzip"
+
+RDEPEND="media-libs/glew:1.6
+	media-libs/libsdl2[opengl,sound,video]
+	media-libs/libvorbis
+	media-libs/openal
+	virtual/glu
+	virtual/opengl"
+
+S="${WORKDIR}/data"
+DOCS=( Linux.README )
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  ${HOMEPAGE}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	local myarch=$(usex amd64 x86_64 x86)
+
+	exeinto "${MYGAMEDIR}"
+	insinto "${MYGAMEDIR}"
+	newexe ${myarch}/superhexagon.${myarch} superhexagon
+	doins -r data SuperHexagon.png
+
+	make_wrapper ${PN} ./superhexagon "${MYGAMEDIR}"
+	newicon -s 512 SuperHexagon.png ${PN}.png
+	make_desktop_entry ${PN}
+
+	einstalldocs
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postinst() { gnome2_icon_cache_update; }
+pkg_postrm() { gnome2_icon_cache_update; }