gnome-extra/gnome-calculator: Version bump to 43.0.1

Closes: https://github.com/gentoo/gentoo/pull/27284
Signed-off-by: brahmajit das <listout@protonmail.com>
Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 74 insertions, 0 deletions

diff --git a/gnome-extra/gnome-calculator/Manifest b/gnome-extra/gnome-calculator/Manifest
index c1581a7d4ffd..4f6ea90cdc9e 100644
--- a/gnome-extra/gnome-calculator/Manifest
+++ b/gnome-extra/gnome-calculator/Manifest
@@ -1 +1,2 @@
 DIST gnome-calculator-42.2.tar.xz 1199392 BLAKE2B 68b6374ac6f86e6d0db29e8839e5b302e1a8d6bc47b7d42c54195e463cfb36d3db6773a771dfb7694fa2c310181b12ddbd171b26b081e9fd9fe8c7b0595ddaee SHA512 81f644a6be66a6ca051c0adbca06eab61bd09f219385631ca2d66fff1c250c01080b3f401ff20b4ee296c0999481c8f1dc1d105521d7995ff682b8e1158ada5a
+DIST gnome-calculator-43.0.1.tar.xz 1205840 BLAKE2B d3044efb5307505485dd55c3401d0c21cc379bcfc6fdd4f0285d093c05e76f9c167c5bd65bdf899c7f3aed892258b65538020a70e690eeb459147e6bea15a94b SHA512 94ec47a03dac017801e9c499aceb2f5f6fd1c79966657c79b123476dc7f3a4a2c3e179c80763e965207b58427157cd6e072260bd79ab98a39eb011cfe3ef7c72
diff --git a/gnome-extra/gnome-calculator/gnome-calculator-43.0.1.ebuild b/gnome-extra/gnome-calculator/gnome-calculator-43.0.1.ebuild
new file mode 100644
index 000000000000..c5167e338b04
--- /dev/null
+++ b/gnome-extra/gnome-calculator/gnome-calculator-43.0.1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A calculator application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Calculator"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+introspection test"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# gtksourceview vapi definitions in dev-lang/vala itself are too old, and newer vala removes them
+# altogether, thus we need them installed by gtksourceview[vala]
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	dev-libs/libxml2:2
+	net-libs/libsoup:3.0
+	>=dev-libs/libgee-0.20.0:0.8
+	dev-libs/mpc:=
+	dev-libs/mpfr:0=
+	>=gui-libs/gtk-4.4.1:4
+	>=gui-libs/libadwaita-1.2.0:1
+	>=gui-libs/gtksourceview-5.3.0:5
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	net-libs/libsoup:3.0[vala]
+	gui-libs/gtksourceview:5[vala]
+	gui-libs/libhandy:1[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-ui=false
+		#-Dvala-version # doesn't do anything in 3.34
+		$(meson_use !introspection disable-introspection)
+		$(meson_use test ui-tests)
+		-Dgcalc=true
+		-Dgci=true
+		-Dapp=true
+		-Ddoc=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}