gnome-extra/gnome-software: Version bump to 40.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/gnome-extra/gnome-software/Manifest b/gnome-extra/gnome-software/Manifest
index 44c73977a869..c2b2f05c330c 100644
--- a/gnome-extra/gnome-software/Manifest
+++ b/gnome-extra/gnome-software/Manifest
@@ -2,3 +2,4 @@ DIST gnome-software-3.34.2.tar.xz 5945736 BLAKE2B 89e7e0a606a832aedbfa32024f201e
 DIST gnome-software-3.36.1.tar.xz 8277796 BLAKE2B bf3d5f3f67b211cfd4af87ae500691085ab83aed9f85e211972d408a1bfa5d7c6de162acc2088bf9ba9323369e73dba27a06b2491745ef2ceb04943e4acbf72d SHA512 7d0e8c16192bbbc8f166db137dbd2e6ff9e85f7d3d37f63f41211ba3838e392bd87a8d9bf09d31b43f6d21e1a099ecdeff9114ae27fae40d563671f0bcbe50d4
 DIST gnome-software-40.0.tar.xz 3087252 BLAKE2B 4b834113c0770a3acfbcf21b5db3d6da57a885e6b235c3328947f218f28daf70c6f636253283dd77d0c4a1fc59f8ac66a140412694a61352147c13c27e7a76af SHA512 052c520ab25af4257bb978aaa9e1c7a555f8d24dbd782d9f12f3c3def22e65588d3c76d16e4b3dc26f034a762c2ee3e773026b158d468e9e169369dc3d156a2a
 DIST gnome-software-40.1.tar.xz 3093832 BLAKE2B 0da79bd28f8db55816543490518dce880878a7619d05d789d4ab1795728025e9eb5ec4ad330018bfae036d3cc79b712178bea9e219b357bb231ee898eb0e1744 SHA512 ae805d01896d761dd82a21dedbfafba7e8ffd2d98e99da4548d846aafdf07f9a26dfa2e083ac2dda576f8b1db05bb3f26642d3a6558da86921450049870767fe
+DIST gnome-software-40.2.tar.xz 3093012 BLAKE2B 0d51e7e752b9399f79c2fc16ea12b99bb58a486fe050e38a8fd606a2afd9db32d67d14b4ed50d21da163238b30fac20f93f8947b165d8ae611c27057dd572d34 SHA512 ded29be4c59130a4016d43d3e18a67c8cf3fec4761a7a57c067bf075a6f1da5b7726000172e2303ba129b3b5cb8bd22ebfad8fbf0e3248285a4864350f3a1679
diff --git a/gnome-extra/gnome-software/gnome-software-40.2.ebuild b/gnome-extra/gnome-software/gnome-software-40.2.ebuild
new file mode 100644
index 000000000000..c81ec02d2b52
--- /dev/null
+++ b/gnome-extra/gnome-software/gnome-software-40.2.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Gnome install & update software"
+HOMEPAGE="https://wiki.gnome.org/Apps/Software"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="flatpak +firmware gnome gtk-doc packagekit spell sysprof udev"
+RESTRICT="test" # writes to and deletes files in /var/tmp/self-test/
+
+RDEPEND="
+	>=dev-libs/appstream-0.14.0:0=
+	>=x11-libs/gdk-pixbuf-2.32.0:2
+	>=dev-libs/libxmlb-0.1.7:=
+	net-libs/gnome-online-accounts:=
+	>=x11-libs/gtk+-3.22.4:3
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/json-glib-1.2.0
+	>=net-libs/libsoup-2.52.0:2.4
+	>=gui-libs/libhandy-1.0.2:1=
+	sysprof? ( >=dev-util/sysprof-capture-3.38.1:4 )
+	gnome? ( >=gnome-base/gsettings-desktop-schemas-3.18.0 )
+	spell? ( app-text/gspell:= )
+	sys-auth/polkit
+	packagekit? ( >=app-admin/packagekit-base-1.1.0 )
+	firmware? ( >=sys-apps/fwupd-1.0.3 )
+	flatpak? (
+		>=sys-apps/flatpak-1.0.4
+		dev-util/ostree
+	)
+	udev? ( dev-libs/libgudev )
+	>=gnome-base/gsettings-desktop-schemas-3.11.5
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+"
+# test? ( dev-util/valgrind )
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e '/install_data.*README\.md.*share\/doc\/gnome-software/d' meson.build || die
+	# We don't need language packs download support, and it fails tests in 3.34.2 for us (if they are enabled)
+	sed -i -e '/subdir.*fedora-langpacks/d' plugins/meson.build || die
+	# Trouble talking to spawned gnome-keyring socket for some reason, even if wrapped in dbus-run-session
+	# TODO: Investigate; seems to work outside ebuild .. test/emerge
+	sed -i -e '/g_test_add_func.*gs_auth_secret_func/d' lib/gs-self-test.c || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dtests=false #$(meson_use test tests)
+		$(meson_use spell gspell)
+		$(meson_feature gnome gsettings_desktop_schemas) # Honoring of GNOME date format settings.
+		-Dman=true
+		$(meson_use packagekit)
+		# -Dpackagekit_autoremove
+		-Dpolkit=true
+		-Deos_updater=false # Endless OS updater
+		$(meson_use firmware fwupd)
+		$(meson_use flatpak)
+		-Dmalcontent=false
+		-Drpm_ostree=false
+		-Dodrs=false
+		$(meson_use udev gudev)
+		-Dapt=false
+		-Dsnap=false
+		-Dexternal_appstream=false
+		-Dvalgrind=false
+		$(meson_use gtk-doc gtk_doc)
+		-Dhardcoded_popular=true
+		-Ddefault_featured_apps=false # TODO: Will this be beneficial to us with flatpak at least? If enabled, it shows some apps under installed (probably merely due to /usr/share/app-info presence), but launching and removal of them is broken
+		-Dmogwai=false #TODO?
+		$(meson_feature sysprof)
+	)
+	meson_src_configure
+}
+
+#src_test() {
+#	virtx meson_src_test
+#}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}