kde-apps: Add KDE Release Service 20.04.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 86 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 004d1119600e..d32b3833b2b6 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1 +1,2 @@
 DIST kwave-19.12.3.tar.xz 6194476 BLAKE2B 98dfcc9922757441b4fbb998f6b2c8c74c14da82ac4811e9b705ba2f6fecd812e2fab8dc840d013be79bcd9b229c432bdb3f938fa6abd933a8898a1593d373ae SHA512 33c045e85aebc4e7ef599a801ebeaf413ce4335fafce109a542cd8af5f83f3748d603698aab48586824cb12a573c6325d7ee20e78d6492a990e7a6650c67e9ba
+DIST kwave-20.04.0.tar.xz 6195272 BLAKE2B bcec360bf743f8cf69cf9ea8d53daec56396750e58432a6a8618d608b92da9c54fc0aaaaa6c2253675eba3e94b99323d8b3d436f5df478ccc24380e862bfb112 SHA512 96cdcc8e1a9d8c951ae11ff4fffd074b87f8f600d8b93c29fa011aae99324295508c6099a6f28cf95aafe25b6c1cb0f003fed82b4b6c6fc9d4c61b6850158b59
diff --git a/kde-apps/kwave/kwave-20.04.0.ebuild b/kde-apps/kwave/kwave-20.04.0.ebuild
new file mode 100644
index 000000000000..7621f3d030e3
--- /dev/null
+++ b/kde-apps/kwave/kwave-20.04.0.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.69.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://kde.org/applications/multimedia/org.kde.kwave"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+RDEPEND="
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| ( media-sound/lame media-sound/toolame media-sound/twolame )
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-apps/poxml-${PVCUT}:5
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}