kde-plasma/plasma-firewall: 5.22.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 65 insertions, 0 deletions

diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index 4ab99b832d81..1c678c767521 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.21.5.tar.xz 331812 BLAKE2B 43a026a198fb61480e90c5a5235de1abbb106e3f78d4a81fe919ec8c65c4f5ca30b340436b28369d8797d9ad1eac87fd0a4e39b5e3670f68150992e6007c4a76 SHA512 93d36b12025f1918892ad02e6b92dc8c44c27d2c6426a19fb77d8b258940a25295acd923b3957d45eb1715dae097097368b0456bf27273c217b79b441dec55fd
 DIST plasma-firewall-5.22.2.tar.xz 339060 BLAKE2B 1d9570900fbd62c9e30da593f95d55e4f6e44892c67e3502e18d040d1c18725b7d308e09c08d1747276f7d0ba5778cc6b3088429a122a60c35674b32ab1cc3c5 SHA512 331a33729d8c8674354045bd6716a6c098672b15cdc882ea07c756630f1683032ec57c5b35da20c9f0a5db54343a307ed6af05f5c1f03a8d906170ffe2a45f9d
+DIST plasma-firewall-5.22.3.tar.xz 339064 BLAKE2B 3c15f9de5e92a719681520e3cfbb57f9ccfd7a0ae09974bb7b3437b1109803783d2c1ca5eccbd29710c0bbf1a586e79142feefd2f681f3f6de5ad186b88824b0 SHA512 7aa54d5e682ca07e4b649d138d3b93af2ee3a579ba0189f046cb7ab4a5c73fc5daf11d08845d0176537d8c40a424559336fbc8e13431b0f1108a169f47977de1
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-5.22.3.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-5.22.3.ebuild
new file mode 100644
index 000000000000..622d3b7334c6
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-5.22.3.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9} )
+KFMIN=5.82.0
+QTMIN=5.15.2
+inherit ecm kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtx11extras-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/plasma-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env python3.8:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}