mate-extra/mate-screensaver: add 1.28.0

Signed-off-by: Ian Jordan <immoloism@gmail.com>
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

2 files changed, 122 insertions, 0 deletions

diff --git a/mate-extra/mate-screensaver/Manifest b/mate-extra/mate-screensaver/Manifest
index 8b5e253fa867..3866b70c5311 100644
--- a/mate-extra/mate-screensaver/Manifest
+++ b/mate-extra/mate-screensaver/Manifest
@@ -1 +1,2 @@
 DIST mate-screensaver-1.26.2.tar.xz 5154752 BLAKE2B 9958647156c84f1c7cc346dc9e0905a07ab626b2fe0913b5108e533e6b7708efceaf3ab3a399f7d6ec73cfccb2173127c13e69a11218bb2f5cb6e6a05f43318d SHA512 00820a431c64e9486258c33f211630060f1f07c36642b90a981dc16cd8b8995140f58118d7ee642002e6ab64d1667556c4682aac4f2f1c02720cb815447287cf
+DIST mate-screensaver-1.28.0.tar.xz 5108156 BLAKE2B 5c78afb2f52fd264da8e62455f53e6a214997d62f604323bdf2149012d62ba14c0435135d6ca22105be5cd46b581799aafd91d18e5caeeacf2cf07c98cc67091 SHA512 c687317d8cb1e5b3844a560dcefb6e198925f8fb54360e1d8a86185e0e15b0bc90046b28ec0a6dc460a2ace15a58c0e7deeac8a8149e5ae83a3e8af8846e796d
diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.28.0.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.28.0.ebuild
new file mode 100644
index 000000000000..b5a5f8ee9f49
--- /dev/null
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.28.0.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit mate readme.gentoo-r1
+
+MINOR=$(($(ver_cut 2) % 2))
+if [[ ${MINOR} -eq 0 ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+fi
+
+DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
+
+LICENSE="GPL-2+ HPND LGPL-2+"
+SLOT="0"
+IUSE="X debug elogind libnotify opengl pam systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+COMMON_DEPEND="
+	>=dev-libs/dbus-glib-0.71:0
+	>=dev-libs/glib-2.58:2
+	gnome-base/dconf
+	>=mate-base/libmatekbd-1.17.0
+	>=mate-base/mate-desktop-1.17.0
+	>=mate-base/mate-menus-1.21.0
+	>=sys-apps/dbus-0.30
+	>=x11-libs/gdk-pixbuf-2.14:2
+	>=x11-libs/libX11-1
+	x11-libs/cairo
+	>=x11-libs/gtk+-3.22:3
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/libXxf86vm
+	x11-libs/libxklavier
+	x11-libs/pango
+	libnotify? ( >=x11-libs/libnotify-0.7:0 )
+	opengl? ( virtual/opengl )
+	pam? ( gnome-base/gnome-keyring sys-libs/pam )
+	!pam? ( kernel_linux? ( sys-apps/shadow ) )
+	elogind? ( sys-auth/elogind )
+	systemd? ( sys-apps/systemd:= )
+"
+
+RDEPEND="${COMMON_DEPEND}
+	>=mate-base/mate-session-manager-1.6
+	virtual/libintl
+	mate-base/mate-panel
+"
+
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8:*
+	x11-base/xorg-proto
+	virtual/pkgconfig:*
+"
+
+DOC_CONTENTS="
+	Information for converting screensavers is located in
+	/usr/share/doc/${PF}/xss-conversion.txt*
+"
+
+src_configure() {
+	local myconf=(
+		--enable-locking
+		--with-kbd-layout-indicator
+		--with-xf86gamma-ext
+		--with-xscreensaverdir=/usr/share/xscreensaver/config
+		--with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+		--without-console-kit
+		$(use_with X x)
+		$(use_with elogind)
+		$(use_with libnotify)
+		$(use_with opengl libgl)
+		$(use_with systemd)
+		$(use_enable debug)
+		$(use_enable pam)
+	)
+
+	mate_src_configure "${myconf[@]}"
+}
+
+src_install() {
+	mate_src_install
+
+	# Install the conversion script in the documentation.
+	dodoc "${S}"/data/migrate-xscreensaver-config.sh
+	dodoc "${S}"/data/xscreensaver-config.xsl
+	dodoc "${FILESDIR}"/xss-conversion.txt
+
+	# Non PAM users will need this suid to read the password hashes.
+	# OpenPAM users will probably need this too when
+	# https://bugzilla.gnome.org/show_bug.cgi?id=370847
+	# is fixed.
+	if ! use pam ; then
+		fperms u+s /usr/libexec/mate-screensaver-dialog
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	mate_pkg_postinst
+
+	if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
+		ewarn "You have a too old xorg-server installation. This will cause"
+		ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
+		echo
+	fi
+
+	if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
+		ewarn "You have xscreensaver installed, you probably want to disable it."
+		ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
+		ewarn "build xscreensaver with -gnome in the USE flags."
+		ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
+		echo
+	fi
+
+	readme.gentoo_print_elog
+}